Updated with real fix for paths

util-linux-2.13_pre6-r1.ebuild (text/plain), 4.47 KB, created by Matthew Schick on 2006-01-21 09:10:34 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.12r-r2.ebuild,v 1.3 2005/12/29 11:40:32 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs

LOOP_AES_VER=3.1c
MY_PV="${PV/_/-}"
MY_P="${PN}-${MY_PV}"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="Various useful Linux utilities"
HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux/"
SRC_URI="mirror://kernel/linux/utils/${PN}/testing/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~x86 ~amd64"
IUSE="crypt static pam selinux perl"

RDEPEND=">=sys-libs/ncurses-5.2-r2
	>=sys-fs/e2fsprogs-1.34
	selinux? ( sys-libs/libselinux )
	pam? ( sys-apps/pam-login )
	crypt? ( app-crypt/hashalot )
	perl? ( dev-lang/perl )"

DEPEND="${RDEPEND}
	sys-devel/gettext
	virtual/os-headers"

yesno() { useq $1 && echo yes || echo no; }

src_unpack() {
	unpack ${A}

	cd "${S}"

	# crypto support
	use crypt && epatch "${FILESDIR}"/${PN}-2.13-loop-aes.patch

	# Fall back to cracklib if default words file doesnt exist #114416
	epatch "${FILESDIR}"/${PN}-2.12r-cracklib-words.patch

	# Fix -f usage with -a and in general
	epatch "${FILESDIR}"/${PN}-2.12q-more-fake-checks-v2.patch

	# Fix mtab updates with `mount --move /foo /bar` #104697
	epatch "${FILESDIR}"/${PN}-2.12q-update-mtab-when-moving.patch

	# A few fixes to beat update_mtab() into submission.
	epatch "${FILESDIR}"/${PN}-2.12q-update_mtab-fixes.patch

	# Use update_mtab() to avoid dups in mtab for 'mount -f'
	epatch "${FILESDIR}"/${PN}-2.12q-use-update_mtab-for-fake.patch

	# Fix unreadable df output when using devfs ... this check is kind of 
	# a hack, but whatever, the output isnt critical at all :P
	[[ -e /dev/.devfsd ]] && epatch "${FILESDIR}"/no-symlink-resolve.patch

	# Add the O option to agetty to display DNS domainname in the issue
	# file, thanks to Marius Mauch <[e-mail]>, bug #22275.
	#
	# NOTE:  Removing this will break future baselayout, so PLEASE
	#        consult with me before doing so.
	epatch "${FILESDIR}"/${PN}-2.11z-agetty-domainname-option.patch

	# Fix french translation typo #75693
	epatch "${FILESDIR}"/${PN}-2.12q-i18n-update.patch

	# Add NFS4 support (kernel 2.5/2.6)
	epatch "${FILESDIR}"/${PN}-2.13-nfsv4.patch

	# ignore managed/kudzu options #70873
	epatch "${FILESDIR}"/${PN}-2.12i-ignore-managed.patch

	# swapon gets confused by symlinks in /dev #69162
	epatch "${FILESDIR}"/${PN}-2.12p-swapon-check-symlinks.patch

	# don't force umask to 022 #93671
	epatch "${FILESDIR}"/${PN}-2.12q-dont-umask.patch

	# fix cal display when using featureless terminals #112406
	epatch "${FILESDIR}"/${PN}-2.12r-cal-dumb-terminal.patch

	# Bug #108988 unable to always seek when omiting frame pointers 
	epatch "${FILESDIR}"/${PN}-2.13-fdisk-frame-pointers.patch

	# fix prefix for installation
	epatch ${FILESDIR}/${PN}-2.13-prefix.patch

	automake || die "automake failed"
	#local mconfigs="MCONFIG"
	#use old-crypt && mconfigs="${mconfigs} ${OLD_CRYPT_P}/MCONFIG"
	#sed -i \
	#	-e "/^HAVE_PAM=/s:no:$(yesno pam):" \
	#	-e "/^HAVE_SELINUX=/s:no:$(yesno selinux):" \
	#	-e "/^DISABLE_NLS=/s:no:$(yesno !nls):" \
	#	-e "/^HAVE_KILL=/s:no:yes:" \
	#	-e "/^HAVE_SLN=/s:no:yes:" \
	#	-e "/^HAVE_TSORT/s:no:yes:" \
	#	-e "s:-pipe -O2 \$(CPUOPT) -fomit-frame-pointer:${CFLAGS}:" \
	#	-e "s:CPU=.*:CPU=${CHOST%%-*}:" \
	#	-e "s:SUIDMODE=.*4755:SUIDMODE=4711:" \
	#	${mconfigs} || die "MCONFIG sed"
}

src_compile() {
	myconf=""
	myconf="${myconf} $(use_with pam) $(use_with selinux) --enable-nls \
			--disable-login-utils --enable-write --enable-raw --enable-rdev \
			--enable-partx --sbindir=/sbin --bindir=/bin"

	append-ldflags $(bindnow-flags)
	use static && append-ldflags -static
	export CC="$(tc-getCC)"

	econf ${myconf} || die "configure failed"
	emake || die "emake failed"

	cd partx
	has_version '>=sys-kernel/linux-headers-2.6' && append-flags -include linux/compiler.h
	emake CFLAGS="${CFLAGS}" || die "make partx failed"

}

src_install() {
	make install DESTDIR="${D}" || die "install failed"
	#einstall || die "install failed"
	dosym ../man8/agetty.8 /usr/share/man/man1/getty.1
	dosbin partx/{addpart,delpart,partx} || die "dosbin"
	use perl || rm -f "${D}"/usr/bin/chkdupexe

	newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop
	newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop

	# man-pages installs renice(1p) but util-linux does renice(8)
	dosym ../man8/renice.8 /usr/share/man/man1/renice.1

	dodoc HISTORY MAINTAINER README VERSION
	docinto examples
	dodoc example.files/*
}