# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils java-pkg

MY_PV=${PV:0:5}
MY_P=${PN}-${MY_PV}

DESCRIPTION="Open source computer assisted translation (CAT) tool written in Java."
HOMEPAGE="http://www.omegat.org/"
SRC_URI="mirror://sourceforge/omegat/OmegaT_src_${PV}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="
	>=virtual/jdk-1.4
	dev-java/ant-core
	app-arch/unzip
	sys-apps/sed
"
RDEPEND="
	>=virtual/jre-1.4
	dev-java/java-config
"

S=${WORKDIR}
MY_INSTALL_DIR="/opt/${MY_P}"

src_unpack() {
	unpack ${A}

	# Fix the path for help documents.
	# It's statically set to the user's home directory in the source.
	local helpPath="\/usr\/share\/doc\/${PF}\/html"
	sed -i "s/\(.*HELP_DIR.*=.*\"\)docs\(\".*\)/\1$helpPath\2/g" \
		src/org/omegat/util/OConsts.java
	epatch ${FILESDIR}/1.4.5.04-helppath.patch
}

src_compile() {
	
	# Build addons
	ant -buildfile "addons/properties-import/build.xml" "jar"

	# Build main project
	# If javadoc.additionalparam isn't there, we get an error.
	ant "jar" "-Djavadoc.additionalparam="
}

src_install() {
	
	# Addons
	java-pkg_jarinto ${MY_INSTALL_DIR}/addons/properties-import
	java-pkg_dojar addons/properties-import/properties_import.jar
	docinto addons/properties-import/
	dodoc addons/properties-import/readme.txt

	# Main package
	mv dist/OmegaT.jar dist/${PN}.jar
	java-pkg_jarinto ${MY_INSTALL_DIR}
	java-pkg_dojar dist/*.jar
	java-pkg_jarinto ${MY_INSTALL_DIR}/plugins/edge
	java-pkg_dojar dist/plugins/edge/nbedge-filter.jar

	exeinto /usr/bin
	make_startup_script

	rm -r release/OmegaT* release/win32*
	docinto ""
	dodoc release/*
	dohtml -r docs/*

	doicon images/*.ico
	make_desktop_entry ${PN} "OmegaT" "/usr/share/pixmaps/OmegaT.ico" "Application;Office"
}

function make_startup_script() {
	local file="${PN}"
	cat > $file <<EOD
#!/bin/bash	

JAVA=\$(java-config -J)
CLASSPATH=\$(java-config --classpath omegat)

\$JAVA -classpath \$CLASSPATH -jar ${MY_INSTALL_DIR}/${PN}.jar
EOD
	doexe $file
}