latex-beamer-3.06.ebuild

latex-beamer-3.06.ebuild (text/plain), 1.14 KB, created by Gour on 2005-10-24 01:47:11 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit latex-package

DESCRIPTION="LaTeX class for creating presentations using a video projector."
HOMEPAGE="http://latex-beamer.sourceforge.net/"
SRC_URI="mirror://sourceforge/latex-beamer/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc-macos ~sparc ~x86"

IUSE=""

DEPEND=">=dev-tex/pgf-0.95
	>=dev-tex/xcolor-2.00"

src_compile() {
	return
}

src_install() {
	# emacs mode for beamer is not being installed...

	dodir /usr/share/texmf/tex/latex/beamer
	cp -pPR base extensions solutions themes \
		${D}/usr/share/texmf/tex/latex/beamer || die

	insinto /usr/share/texmf/tex/latex/beamer/emulation
	doins emulation/*.sty || die

	for dir in examples emulation/examples ; do
		insinto /usr/share/doc/${PF}/$dir
		doins $dir/*
	done

	if has_version 'app-office/lyx' ; then
		insinto /usr/share/lyx/layouts
		doins lyx/layouts/beamer.layout
		insinto /usr/share/lyx/examples
		doins lyx/examples/*
		doins solutions/*/*.lyx
	fi

	dodoc AUTHORS ChangeLog FILES TODO README
	insinto /usr/share/doc/${PF}
	doins doc/*
}