# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="Biloba is a board game, up to 4 players, with AI and network."
HOMEPAGE="http://perso.wanadoo.fr/biloba/"
SRC_URI="mirror://sourceforge/biloba/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="esd"

RDEPEND="virtual/x11
	>=media-libs/libsdl-1.2.4
	>=media-libs/sdl-image-1.2
	esd? ( media-sound/esound )"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}

	# /usr/share/games != /usr/games/share
	cd "${S}"
	sed -i "s:^\(datadir\) = .*:\1 = ${GAMES_DATADIR}/biloba:" \
		src/Makefile.in
	sed -i "s:^\(bilobadir\) = .*/\(.*\):\1 = ${GAMES_DATADIR}/biloba/\2:" \
		res/*/Makefile.in
}

src_compile() {
	egamesconf $(use_enable esd) || die "Configuration failed"
	emake || die "Make failed"
}

src_install() {
	make DESTDIR=${D} install || die "Installation failed"
	dodoc AUTHORS ChangeLog README
	newicon biloba_icon.png biloba.png
	make_desktop_entry biloba Biloba
}