new ebuild

jython-2.2_alpha1.ebuild (text/plain), 2.72 KB, created by Santiago Gala on 2005-09-17 00:33:30 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/jython/jython-2.1-r6.ebuild,v 1.3 2005/07/09 16:06:00 axxo Exp $

inherit java-pkg

DESCRIPTION="An implementation of Python written in Java"
HOMEPAGE="http://www.jython.org"
MY_PV="Release_2_2alpha1"
# uses CPython library from version...
PYVER="2.2"
SRC_URI="mirror://sourceforge/${PN}/${PN}_${MY_PV}.jar"
#SRC_URI="mirror://gentoo/${P}.tar.bz2"
LICENSE="JPython"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~amd64 ~ppc64"
IUSE="readline jikes source doc servlet"

RDEPEND=">=virtual/jre-1.2
	readline? ( >=dev-java/libreadline-java-0.8.0 )"
DEPEND=">=virtual/jdk-1.2 
    dev-java/ant
	=dev-lang/python-${PYVER}*
	source? ( app-arch/zip )
	jikes? ( >=dev-java/jikes-1.18 )
	servlet? ( dev-java/servletapi )
	${RDEPEND}"

src_compile() {
	# don't know how to dynamically find a python library
	local pylib=$(python${PYVER} -c 'import site; print "/".join(site.__file__.split("/")[:-1])')
	local antflags="--noconfig -Dbase.path=src/java -Dsource.dir=src/java
	             -Dpython.lib=${pylib} -Dpython.exe=/usr/bin/python${PYVER}"
	use jikes && antflags="${antflags} -Dbuild.compiler=jikes"
	use readline && antflags="${antflags} -Dreadline.present=yes
	             -Dreadline.jar=$(java-config --classpath libreadline-java)"
	# not really need 2.4, but java-config will not answer without a slot
	use servlet && antflags="${antflags} -Dservlet.present=yes
	              -Dservlet.jar=$(java-pkg_getjars servletapi-2.4)"
	
	cd ${WORKDIR}
	# patch a small error in build.xml
	sed -ie 's@"org/python/modules@"${source.dir}/org/python/modules@' build.xml
	# another one
	cp -r build.Lib.include.properties Lib src/java
	# LC_ALL=C prevents java failing in utf-8 filesystems
	LC_ALL=C ant ${antflags} || die "compile failed"
}

src_install() {

	cd ${WORKDIR}
	java-pkg_dojar dist/${PN}.jar
	dodoc README.txt NEWS ACKNOWLEDGMENTS
	use doc && java-pkg_dohtml -A .css .jpg .gif -r Doc/*
	newbin ${FILESDIR}/jython jython
	newbin ${FILESDIR}/jythonc jythonc

	# Not in a multiuser system
	#dodir /usr/share/jython/cachedir
	#chmod -R a+rw ${D}/usr/share/jython/cachedir

	insinto /usr/share/${PN}
	doins -r dist/Lib

	insinto /usr/share/${PN}/tools
	doins -r Tools/*

	use source && java-pkg_dosrc org src/java/*
}

pkg_postinst() {
	if use readline; then
		einfo "To use readline you need to add the following to your registery"
		einfo
		einfo "python.console=org.python.util.ReadlineConsole"
		einfo "python.console.readlinelib=GnuReadline"
		einfo
		einfo "The global registry can be found in /usr/share/${PN}/registry"
		einfo "User registry in \$HOME/.jython"
		einfo "See http://www.jython.org/docs/registry.html for more information"
	fi
}