Build shared library for X's dlloader, properly PIC

synaptics-0.14.3-r1.ebuild (text/plain), 2.46 KB, created by Kevin F. Quinn (RETIRED) on 2005-09-08 11:56:13 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/synaptics/synaptics-0.14.3.ebuild,v 1.6 2005/08/20 18:32:29 battousai Exp $

inherit toolchain-funcs eutils

DESCRIPTION="Driver for Synaptics touchpads"
HOMEPAGE="http://w1.894.telia.com/~u89404340/touchpad/"
SRC_URI="http://w1.894.telia.com/~u89404340/touchpad/files/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="dlloader"
RDEPEND="virtual/x11"
DEPEND=">=sys-apps/sed-4"

src_unpack() {
	unpack ${A}

	cd ${S}

	epatch ${FILESDIR}/${PN}-0.14.x-gcc4-the-sentinels-have-attacked.patch

	# Put stuff into /usr, also switch up the CC and CFLAGS stuff.
	sed -i -e "s:BINDIR = \\\$(DESTDIR)/usr/local/bin:BINDIR = ${D}/usr/bin:g
				s:CC = gcc:CC = $(tc-getCC):g
				s:CDEBUGFLAGS = -O2:CDEBUGFLAGS = ${CFLAGS}:g
				s:MANDIR = .*:MANDIR = \\\$(DESTDIR)/usr/share/man:
				s:INSTALLED_X = .*:INSTALLED_X = \\\$(DESTDIR)/usr:" \
				${S}/Makefile || die "sed Makefile for Gentoo failed"
	if use dlloader || has_version ">=x11-base/xorg-x11-6.8.99.15"; then
		# Change CFLAGS to LIBCFLAGS, used when building objects for the
		# library and add-fPIC added to LIBCFLAGS. Set -shared instead of
		# -r, and build synaptics_drv.so instead of synaptics_drv.o
		# Install shared library as executable (note; this last uses a
		# specific line-number, so is likely to need adjustment if the
		# Makefile changes upstream).
		# Remove forcing of -fno-pic everywhere.
		sed -i -e "s:^CFLAGS = :LIBCFLAGS = -fPIC :
					s:\$(CFLAGS):\$(LIBCFLAGS):
					s:synaptics_drv.o:synaptics_drv.so:g
					s:LDCOMBINEFLAGS = .*:LDCOMBINEFLAGS = -shared:
					s:^\(.*-fno-pic.*\)$:#\1:
					99 s:0644:0755:" \
					${S}/Makefile || die "sed Makefile for Xorg dlloader failed"
	fi
}

src_install() {
	dodir /usr/$(get_libdir)/modules/input

	# Yes, they got the DESTDIR stuff going. And there was much rejoicing.
	make DESTDIR=${D} install || die
	dodoc {script/usbmouse,alps.patch,COMPATIBILITY,FILES,INSTALL{,.DE},LICENSE,NEWS,TODO,README{,.alps}}
	# Stupid new daemon, didn't work for me because of shm issues
	exeinto /etc/init.d && newexe ${FILESDIR}/rc.init syndaemon
	insinto /etc/conf.d && newins ${FILESDIR}/rc.conf syndaemon
}

pkg_postinst() {
	einfo "You will need to do some further configuration:"
	einfo "  1) Kernel configuration, kernel module autoload"
	einfo "  2) Xorg.conf setup"
	einfo "See INSTALL doc in /usr/share/doc/${PF} for details"
}