# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/quake3/quake3-1.32b-r3.ebuild,v 1.19 2005/05/12 12:38:40 wolf31o2 Exp $

ESVN_REPO_URI="svn://svn.icculus.org/quake3/trunk"
inherit subversion games toolchain-funcs

DESCRIPTION="Quake III Arena - 3rd installment of the classic id 3D first-person shooter"
HOMEPAGE="http://icculus.org/quake3/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-*"
IUSE="opengl"

RDEPEND="opengl? ( virtual/opengl virtual/x11 )"

S=${WORKDIR}/trunk

src_unpack() {
	subversion_src_unpack
	cd "${S}"
	chmod a+rx code/unix/extract_ver.pl
}

src_compile() {
	emake \
		CC="$(tc-getCC)" \
		OPTIMIZE="${CFLAGS}" \
		DEFAULT_BASEDIR="${GAMES_DATADIR}/quake3" \
		release || die
}

src_install() {
	dodoc README.txt i_o-q3-readme
	cd code/unix
	dodoc ChangeLog README*

	doicon quake3.xpm
	make_desktop_entry quake3 "Quake III Arena" quake3.xpm

	cd release*
	for x in linux* ; do
		newgamesbin ${x} ${x/linux} || die "dobin ${x}"
	done
	exeinto ${GAMES_LIBDIR}/${PN}/baseq3
	doexe baseq3/*.so || die "baseq3 .so"
	exeinto ${GAMES_LIBDIR}/${PN}/missionpack
	doexe missionpack/*.so || die "missionpack .so"

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	echo
	ewarn "There are two possible security bugs in this package, both causing a	denial"
	ewarn "of service.  One affects the game when running a server, the other when running"
	ewarn "as a client.  For more information, see bug #82149."
	echo
	einfo "You need to copy pak0.pk3 from your Quake3 CD into ${GAMES_DATADIR}/quake3/baseq3."
	einfo "Or if you have got a Window installation of Q3 make a symlink to save space."
}