an ebuild for the latest iproute2 release

iproute2-050816.ebuild (text/plain), 1.64 KB, created by scott on 2005-08-19 09:15:57 UTC

inherit eutils toolchain-funcs

DESCRIPTION="kernel routing and traffic control utilities"
HOMEPAGE="http://developer.osdl.org/dev/iproute2/"
SRC_URI="http://developer.osdl.org/dev/iproute2/download/${PN}-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="atm berkdb minimal"

RDEPEND="!minimal? ( berkdb? ( sys-libs/db ) )
	atm? ( net-dialup/linux-atm )"
DEPEND="${RDEPEND}
	>=virtual/os-headers-2.4.21"

S=${WORKDIR}/${PN}-${PV}

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i -e "s:-O2:${CFLAGS}:" Makefile || die "sed Makefile failed"
	epatch "${FILESDIR}"/iproute2-2.6.11.20050330-stack.patch
	#68948 - esfq/wrr patches
	epatch \
		"${FILESDIR}"/2.6.12-rc1-esfq.patch \
		"${FILESDIR}"/iproute2-2.6.11.20050330-wrr.patch
	# don't build arpd if USE=-berkdb #81660
	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
	# Multilib fixes
	sed -i 's:/usr/local:/usr:' tc/m_ipt.c
	sed -i "s:/usr/lib/tc:/usr/$(get_libdir)/tc:g" \
		tc/Makefile tc/tc.c tc/q_netem.c || die
}

src_compile() {
	echo -n 'TC_CONFIG_ATM:=' > Config
	use atm \
		&& echo 'y' >> Config \
		|| echo 'n' >> Config

	local SUBDIRS="lib ip tc misc netem"
	use minimal && SUBDIRS="lib tc"
	emake \
		CC="$(tc-getCC)" \
		AR="$(tc-getAR)" \
		SUBDIRS="${SUBDIRS}" \
		|| die "make"
}

src_install() {
	if use minimal; then
		into /
		dosbin tc/tc || die "minimal"
		return 0
	fi

	make \
		DESTDIR="${D}" \
		SBINDIR=/sbin \
		DOCDIR=/usr/share/doc/${PF} \
		install \
		|| die "make install failed"
	if use berkdb ; then
		# bug 47482, arpd doesn't need to be in /sbin
		dodir /usr/sbin
		mv "${D}"/sbin/arpd "${D}"/usr/sbin/
	fi
}