# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gnome2 cvs mono eutils

DESCRIPTION="A Mono/GStreamer Based Music Player"
HOMEPAGE="http://sonance.aaronbock.net/"
SRC_URI=""
MY_PN="sonance"
ECVS_SERVER="anoncvs.gnome.org:/cvs/gnome"
ECVS_MODULE="${MY_PN}"
ECVS_TOP_DIR="${DISTDIR}/cvs-src/${MY_PN}"
MY_PV_DATE="${PV#*_pre}"
ECVS_CO_OPTS="-D ${MY_PV_DATE}"
ECVS_UP_OPTS="-dP ${ECVS_CO_OPTS}"
S="${WORKDIR}/${ECVS_MODULE}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="real"

RDEPEND=">=dev-lang/mono-1.0.0
	>=dev-dotnet/gtk-sharp-1.9
	>=dev-dotnet/gnome-sharp-1.9
	>=dev-dotnet/gnomevfs-sharp-1.9
	>=dev-dotnet/glade-sharp-1.9
	>=dev-dotnet/gconf-sharp-1.9
	>=dev-dotnet/ipod-sharp-0.4.9
	sys-apps/dbus
	>=dev-db/sqlite-2.8.15
	>=media-libs/gstreamer-0.8.8
	>=media-libs/gst-plugins-0.8.7
	>=gnome-base/gconf-2.0
	>=x11-libs/gtk+-2.4
	>=gnome-base/gnome-vfs-2.0
	>=gnome-base/gnome-desktop-2.0
	gnome-extra/nautilus-cd-burner"
# real? ( media-libs/hxclientkit ) -- currently included as a prebuilt .{a,so}

DEPEND="${RDEPEND}
	gnome-base/gnome-common
	dev-util/pkgconfig"

G2CONF="$(use_enable real helix)"

pkg_setup() {
	if ! built_with_use sys-apps/dbus mono; then
		die "need sys-apps/dbus built with mono USE flag"
	fi
}
	
src_compile() {
	./autogen.sh --prefix=/usr || die "Autogen failure"
	gnome2_src_compile
}

src_install() {
	gnome2_src_install
	dosym /usr/bin/banshee /usr/bin/sonance
}

DOCS="AUTHORS ChangeLog NEWS README"