warzone2100-0.2.ebuild

warzone2100-0.2.ebuild (text/plain), 1.26 KB, created by SpanKY on 2005-06-28 17:47:02 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Warzone 2100, the 3D real-time strategy game"
HOMEPAGE="http://warzone2100.sourceforge.net/"
SRC_URI="mirror://sourceforge/warzone2100/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="opengl openal ogg mp3"

DEPEND=">=media-libs/libsdl-1.2.8
	>=media-libs/sdl-net-1.2.5
	opengl? ( virtual/opengl )
	openal? ( >=media-libs/openal-20040817 )
	ogg? ( >=media-libs/libvorbis-1.1.0 media-libs/libogg )
	mp3? ( >=media-libs/libmad-0.15 )"

S=${WORKDIR}

src_unpack() {
	unpack ${A}
	cd "${S}"
	./autogen.sh || die "autotools failed"
}

src_compile() {
	# $(use_with cda) ... cda disables ogg/mp3
	egamesconf \
		$(use_with opengl) \
		$(use_with openal) \
		$(use_with ogg) \
		$(use_with mp3) \
		|| die "egamesconf failed"
	emake || die "emake failed"
}

src_install() {
	# As the game can't install itself automatically yet, we've got to do it
	# manually.
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r data || die "doins data"
	exeinto "${GAMES_LIBDIR}"/${PN}
	doexe src/warzone || die "doexe failed"
	dodoc AUTHORS CHANGELOG README

	games_make_wrapper ${PN} "${GAMES_LIBDIR}"/${PN}/warzone "${GAMES_DATADIR}/${PN}"
	prepgamesdirs
}