backport-util-concurrent-1.1.01.ebuild

backport-util-concurrent-1.1.01.ebuild (text/plain), 1.01 KB, created by Josh Nichols (RETIRED) on 2005-06-20 17:07:51 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-pkg

MY_PV="1.1_01"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="This package is the backport of java.util.concurrent API, introduced in Java 5.0, to Java 1.4"
HOMEPAGE="http://www.mathcs.emory.edu/dcl/util/backport-util-concurrent/"
SRC_URI="http://www.mathcs.emory.edu/dcl/util/${PN}/dist/${MY_P}/${MY_P}-src.tar.bz2"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~x86"
IUSE="jikes doc"

DEPEND="virtual/jdk
	dev-java/ant
	dev-java/junit
	jikes? (dev-java/jikes)"
RDEPEND="virtual/jre"
S="${WORKDIR}/${MY_P}-src"

src_unpack() {
	unpack ${A}
	cd ${S}/external
	java-pkg_jar-from junit
}

src_compile() {
	local antflags="javacompile archive"
	use jikes && antflags="-Dbuild.compiler=jikes ${antflags}"
	use doc && antflags="${antflags} javadoc"

	ant ${antflags} || die "Compilation failed"
}

src_install() {
	java-pkg_dojar ${PN}.jar
	use doc && java-pkg_dohtml -r doc/api
	java-pkg_dohtml README.html
}