# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gnome2 eutils

DESCRIPTION="A nautilus plugin to easily share folders over the SMB protocol"
HOMEPAGE="http://gentoo.ovibes.net/nautilus-share"
SRC_URI="http://gentoo.ovibes.net/${PN}/${P}.tar.gz"
IUSE=""
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86"

RDEPEND="
	>=gnome-base/nautilus-2.5.0
	>=gnome-base/eel-2.5.0
	>=dev-libs/glib-2.4.0
	>=gnome-base/libglade-2.4.0
	>=sys-apps/dbus-0.23
	>=dev-libs/libdaemon-0.7
	>=x11-themes/gnome-icon-theme-2.10.1"

DOCS="AUTHORS ChangeLog NEWS README TODO"

G2CONF="--with-dbus-sys=/etc/dbus-1/system.d"

USE_DESTDIR="1"

pkg_setup() {
	if ! built_with_use sys-apps/dbus gtk; then
		eerror "Need GLib support in DBUS."
		eerror "Please re-emerge sys-apps/dbus with gtk USE flag enabled."
		die "unmet dependencies"
	fi
}

src_unpack() {
	unpack ${A}
	cd ${S}
	if has_version '>=sys-apps/dbus-0.30'; then
		einfo "Applying dbus-0.30 API change patches..."
		epatch ${FILESDIR}/${PN}-0.5.1-dbus-api.patch
		epatch ${FILESDIR}/${PN}-0.5.1-dbus-api-2.patch
		epatch ${FILESDIR}/${PN}-0.5.1-dbus-api-3.patch
	fi
	epatch ${FILESDIR}/${PN}-0.5.1-stock-icon.patch
}

src_install() {
	gnome2_src_install "$@"

	if has_version '>=sys-apps/dbus-0.30'; then
		dodir /usr/share/dbus-1/services
		cat >${D}/usr/share/dbus-1/services/net.ovibes.dbus.smbparser.service \
		<<END
[D-BUS Service]
Names=net.ovibes.dbus.smbparser.Service;
Exec=/usr/bin/smbshared
END
	fi
	
	# debian only
	rm -r ${D}/etc/dbus-1/event.d
	doinitd ${FILESDIR}/smbshared
	
	# smb.conf hackery
	dodir /etc/samba
	touch ${D}/etc/samba/smbshared.conf
	chmod 644 ${D}/etc/samba/smbshared.conf
	if [[ -r /etc/samba/smb.conf ]]; then
		if ! grep 'include[[:space:]]*=[[:space:]]*/etc/samba/smbshared.conf' \
			-q /etc/samba/smb.conf
		then
			cp /etc/samba/smb.conf ${D}/etc/samba/smb.conf
			cat >> ${D}/etc/samba/smb.conf <<END

# directive to enable gnome-extra/nautilus-share
include = /etc/samba/smbshared.conf

END
			chmod 644 ${D}/etc/samba/smb.conf
		fi
	else
		cat >${D}/etc/samba/smb.conf <<END
[global]
workgroup =  WORKGROUP
security = share
# directive to enable gnome-extra/nautilus-share
include = /etc/samba/smbshared.conf
END
		chmod 644 ${D}/etc/samba/smb.conf
	fi
}

pkg_postinst() {
	einfo "To get nautilus-share working, issue the following commands as root:"
	echo
	einfo "rc-update add smbshared default"
	einfo "/etc/init.d/dbus restart"
	einfo "/etc/init.d/smbshared start"
	echo
	einfo "Then, as your current user, restart nautilus (killall nautilus)"
}

pkg_postrm() {
	if ! has_version ${CATEGORY}/${PN}; then
		if [[ -r /etc/samba/smb.conf ]] && \
			grep 'include[[:space:]]*=[[:space:]]*/etc/samba/smbshared.conf' \
			-q /etc/samba/smb.conf
		then
			ewarn "You may wish to remove the line"
			ewarn "        include = /etc/samba/smbshared.conf"
			ewarn "from /etc/samba/smb.conf"
		fi
	fi
}