# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/pmd/pmd-1.5-r1.ebuild,v 1.4 2005/04/21 14:47:32 luckyduck Exp $

inherit eutils java-pkg

DESCRIPTION="PMD is a Java source code analyzer. It finds unused variables, empty catch blocks, unnecessary object creation and so forth."
HOMEPAGE="http://pmd.sourceforge.net"
SRC_URI="mirror://sourceforge/pmd/${PN}-src-${PV}.zip"
LICENSE="pmd"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~ppc ~sparc"
IUSE="doc jikes"

DEPEND=">=virtual/jdk-1.3
	app-arch/unzip
	>=dev-java/ant-1.6
	>=dev-java/xerces-2.6.2-r1
	dev-java/saxpath
	=dev-java/jaxen-1.0*
	>=dev-java/junit-3.8.1"

RDEPEND="|| ( >=virtual/jdk-1.3 >=virtual/jre-1.3 )"

src_unpack() {
	unpack ${A}

	cd ${S}/lib/

	rm -f *.jar

	java-pkg_jar-from saxpath saxpath.jar saxpath-1.0-fcs.jar
	java-pkg_jar-from jaxen jaxen-full.jar jaxen-core-1.0-fcs.jar
	java-pkg_jar-from xerces-2 xercesImpl.jar xercesImpl-2.6.2.jar
	java-pkg_jar-from xerces-2 xmlParserAPIs.jar xmlParserAPIs-2.6.2.jar

	cd ${S}

	epatch ${FILESDIR}/${P}-classpath.patch
}

src_compile() {
	local antflags="dist"

	use jikes && antflags="${antflags} -Dbuild.compiler=jikes"

	cd bin

	ant ${antflags} || die "died on ant"
}

src_install() {
	java-pkg_dojar lib/${PN}-${PV}.jar

	dodir /usr/share/ant-core/lib

	dosym /usr/share/${PN}/lib/${PN}-${PV}.jar /usr/share/ant-core/lib/${PN}.jar

	keepdir /usr/share/ant-core/lib/ext/

	cd ${D}/usr/share/ant-core/lib/ext

	java-pkg_jar-from saxpath saxpath.jar saxpath-1.0-fcs.jar
	java-pkg_jar-from jaxen jaxen-full.jar jaxen-core-1.0-fcs.jar

	use doc && java-pkg_dohtml -r docs/*
}