freeciv-2.0.1.ebuild

freeciv-2.0.1.ebuild (text/plain), 2.32 KB, created by TGL on 2005-04-30 05:51:48 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

MY_P=${PN}-${PV/_/-}
S="${WORKDIR}/${MY_P}"
DESCRIPTION="multiplayer strategy game (Civilization Clone)"
HOMEPAGE="http://www.freeciv.org/"
SRC_URI="ftp://ftp.freeciv.org/pub/freeciv/stable/${MY_P}.tar.bz2
http://www.freeciv.org/ftp/contrib/sounds/sets/stdsounds2.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="Xaw3d gtk gtk2 nls readline dedicated"

RDEPEND="sys-libs/zlib
	readline? ( sys-libs/readline )
	!dedicated (
		virtual/x11
		!gtk? ( Xaw3d? ( x11-libs/Xaw3d ) )
		gtk? (
			gtk2? (
				>=x11-libs/gtk+-2.0.0
				>=dev-libs/glib-2.0.0
				>=dev-libs/atk-1.0.3
				>=x11-libs/pango-1.0.5
			)
			!gtk2? (
				=x11-libs/gtk+-1*
				>=dev-libs/glib-1.2.5
				>=media-libs/imlib-1.9.2
			)
		)
	)"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}

	# install locales in /usr/share/locale
	sed -i 's:^\(localedir = \).*:\1/usr/share/locale:' \
		${S}/intl/Makefile.in ${S}/po/Makefile.in.in || die "sed failed"
	sed -i '/^#define LOCALEDIR/s:".*":"/usr/share/locale":' \
		${S}/configure || die "sed failed"

	# install the .desktop in /usr/share/applications
	sed -i 's:^\(desktopfiledir = \).*:\1/usr/share/applications:' \
		${S}/client/Makefile.in || die "sed failed"

	# remove civclient manpage if dedicated server
	use dedicated && {
		sed -i '/man_MANS = /s:civclient.6::' \
			${S}/doc/man/Makefile.in || die "sed failed"
	}
}

src_compile() {
	local myclient="xaw"
	use Xaw3d && myclient="xaw3d"
	if use gtk ; then
		use gtk2 \
			&& myclient="gtk-2.0" \
			|| myclient="gtk"
	fi
	use dedicated && myclient="no"

	egamesconf \
		--disable-dependency-tracking \
		--with-zlib \
		$(use_with readline) \
		$(use_enable nls) \
		--enable-client=${myclient} \
		|| die "egamesconf failed"

	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"

	if use '!dedicated' ; then
		insinto /usr/lib/X11/app-defaults
		doins data/Freeciv || die "doins failed"
		# install sounds
		cp -R ${WORKDIR}/stdsounds* "${D}${GAMES_DATADIR}/${PN}" \
			|| die "failed to install sounds"
	fi

	dodoc ChangeLog INSTALL NEWS \
		doc/{BUGS,CodingStyle,HACKING,HOWTOPLAY,PEOPLE,README*,TODO} \
			|| die "dodoc failed"

	prepgamesdirs
}