# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils

DESCRIPTION="Gourmet Recipe Manager allows you to collect, search and organize your recipes, and to automatically generate shopping lists from your collection."
HOMEPAGE="http://grecipe-manager.sourceforge.net/"
SRC_URI="mirror://sourceforge/grecipe-manager/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND=">=dev-lang/python-2.2
	>=dev-python/pygtk-2.3.93
	=dev-python/gnome-python-2*
	=gnome-base/libglade-2*
	dev-db/metakit
	dev-python/imaging"

DOCS="README TODO PKG-INFO CHANGES"

pkg_setup() {
	if ! built_with_use '>=dev-python/pygtk-2.3.93' gnome ; then
		eerror "You need to install pygtk with libglade support. Try:"
		eerror "USE='gnome' emerge pygtk"
		die "libglade support missing from pygtk"
	fi
	if ! built_with_use 'dev-db/metakit' python ; then
		eerror "You need to install metakit with python support. Try:"
		eerror "USE='python' emerge metakit"
		die "python support missing from metakit"
	fi
}

src_install() {
	distutils_src_install --disable-modules-check
}