advancemame-0.61.4.ebuild

advancemame-0.61.4.ebuild (text/plain), 2.44 KB, created by Bret Towe on 2002-11-10 04:03:52 UTC

# Copyright 1999-2002 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/app-emulation/advancemame/advancemame-0.61.1.ebuild,v 1.2 2002/08/26 18:28:46 azarah Exp $

# This build we configure to explicitly use SDL, as it is very
# difficult to get it working with fb or svgalib support.  Anyway,
# it do not look as good ;-)

# Snapshot support
SNAPSHOT=""

MY_PV="$(echo ${PV} | cut -d. -f1,2)"
S="${WORKDIR}/${P}"
DESCRIPTION="AdvanceMAME is a GNU/Linux port of the MAME emulator, with GUI menu."
# Handle snapshots differently
if [ -z "${SNAPSHOT}" ] ; then
	SRC_URI="mirror://sourceforge/advancemame/${P}.tar.gz"
	MY_A="${P}.zip"
else
	SRC_URI="http://www.ibiblio.org/gentoo/distfiles/${PN}-${SNAPSHOT}.tar.bz2"
	MY_A="${PN}-${SNAPSHOT}.tar.bz2"
fi
SRC_URI="${SRC_URI}
	http://mbnet.fi/~gridle/mame${MY_PV/\.}s.zip
	http://www.mame.net/zips/mame${MY_PV/\.}s.zip
	http://roms.mame.dk/emu/mame${MY_PV/\.}s.zip"
HOMEPAGE="http://advancemame.sourceforge.net/"

LICENSE="GPL-2 xmame"
SLOT="0"
KEYWORDS="x86"

DEPEND="virtual/x11
	app-arch/unzip
	>=dev-lang/nasm-0.98
	>=media-libs/libsdl-1.2.3"


src_unpack() {
	# unpack advance mame
	# Handle snapshots differently
	if [ -z "${SNAPSHOT}" ] ; then
		unpack ${P}.tar.gz || die
	else
		unpack ${PN}-${SNAPSHOT}.tar.bz2 || die
	fi
	
	cd ${S}

	unpack mame${MY_PV/\.}s.zip
	# Unpack mame
	unzip -aa MAME.ZIP || die
	rm -f MAME.ZIP makefile
	
	cd src
	# Apply the advancemame patch to the mame sources
	patch -p1 < ${S}/advance/advmame.dif || die

	# Fix manpage/doc install location
	cd ${S}
	cp advance/advance.mak advance/advance.mak.orig
	sed -e 's:$(PREFIX)/doc/advance:$(PREFIX)/share/doc/${PF}:g' \
	    -e 's:$(PREFIX)/man/man1:$(PREFIX)/share/man/man1:g' \
	    advance/advance.mak.orig > advance/advance.mak

	# fix slang include problem
	patch -p0 < ${FILESDIR}/advancemame-gentoo.diff
}

src_compile() {
	cd ${S}
	# Configure with explicit SDL support
	myconf="--with-emu=mame"
	econf ${myconf} || die
		
	emake || die
}

src_install() {
	cd ${S}
	# The install script does not create this one
	dodir /usr/bin
	make PREFIX=${D}/usr install || die

	dodoc COPYING whatsnew.txt
	dodoc docs/{ctrlr.txt,listinfo.txt,mame.txt}
	# Zip the docs that was installed by 'make install'
	gzip ${D}/usr/share/doc/${PF}/*.txt

	# Move the html pages the the correct location
	dodir /usr/share/doc/${PF}/html
	mv ${D}/usr/share/doc/${PF}/*.html ${D}/usr/share/doc/${PF}/html
}