libao-0.8.6-r1.ebuild

libao-0.8.6-r1.ebuild (text/plain), 1.69 KB, created by Przemyslaw Maciag (RETIRED) on 2005-03-15 13:05:56 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:

inherit libtool eutils

DESCRIPTION="the audio output library"
HOMEPAGE="http://www.xiph.org/ao/"
SRC_URI="http://downloads.xiph.org/releases/ao/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~ppc-macos ~sparc ~x86"
IUSE="alsa arts esd nas mmap static"

DEPEND="virtual/libc
	>=sys-apps/sed-4
	alsa? ( media-libs/alsa-lib )
	arts? ( kde-base/arts )
	esd? ( >=media-sound/esound-0.2.22 )
	nas? ( media-libs/nas )"

src_unpack() {
	unpack ${A}

	cd ${S}
	epatch ${FILESDIR}/${P}-ppc-macos.patch
	epatch ${FILESDIR}/${P}-darwin_configure.patch

	elibtoolize
}

src_compile() {
	# this is called alsa09 even if it is alsa 1.0
	econf \
		`use_enable alsa alsa09` \
		`use_enable mmap alsa09-mmap` \
		`use_enable arts` \
		`use_enable esd` \
		`use_enable nas` \
		--enable-shared \
		`use_enable static` || die "configure failed"

	# See bug #37218.  Build problems with parallel make.
	emake -j1 || die "make failed"
}

src_install () {
	make DESTDIR=${D} install || die "make install failed"

	rm -rf ${D}/usr/share/doc
	dodoc AUTHORS CHANGES COPYING README TODO
	dohtml -A c doc/*.html

	# problems with missing *dylib postfix in filenames on ppc-macos
	# this need a patch - above is a hakish workaround
	# with creating symlinks
	if use ppc-macos; then
		cd ${D}/usr/lib
		for i in `ls ${PN}.2*`; do
			dosym ${i} /usr/lib/${i}.dylib
		done
		dosym ${PN} /usr/lib/${PN}.a
	fi

	insinto /etc
	doins ${FILESDIR}/${PN}.conf
}

pkg_postinst() {
	echo
	einfo "In /etc/libao.conf I placed sample configuration file"
	einfo "for you. Edit it and tune to your needs"
	echo
}