# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-simulation/openttd/openttd-0.3.5.ebuild,v 1.2 2004/12/28 10:06:14 dholm Exp $

inherit eutils games

DESCRIPTION="OpenTTD is a clone of Transport Tycoon Deluxe"
HOMEPAGE="http://www.openttd.com/"
SRC_URI="mirror://sourceforge/openttd/${P}-source.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~amd64"
IUSE="debug png zlib timidity alsa pmidi"

DEPEND="virtual/libc
	media-libs/libsdl
	png? ( media-libs/libpng )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	timidity? ( media-sound/timidity++ )
	!timidity? ( ||(
			pmidi?(media-sound/pmidi) 
		 	alsa?(media-sound/alsa-utils) 
			)
		   )"

src_compile() {
	local myopts="MANUAL_CONFIG=1 UNIX=1 WITH_SDL=1 WITH_NETWORK=1 INSTALL=1 RELEASE=${PV} USE_HOMEDIR=1 PERSONAL_DIR=.openttd PREFIX=/usr DATA_DIR=share/games/${PN}"
	use debug && myopts="${myopts} DEBUG=1"
	use png && myopts="${myopts} WITH_PNG=1"
	use zlib && myopts="${myopts} WITH_ZLIB=1"
	if ! use timidity; then
		if use pmidi; then
			myopts="${myopts} MIDI=/usr/bin/pmidi"
		else
			use alsa && myopts="${myopts} MIDI=/usr/bin/aplaymidi"
		fi
	fi

	emake -j1 ${myopts} || die "emake failed"
}

src_install() {
	dogamesbin openttd || die "dogamesbin failed"

	insinto "${GAMES_DATADIR}/${PN}/data"
	doins data/* || die "doins failed"

	insinto "${GAMES_DATADIR}/${PN}/lang"
	doins lang/*.lng || die "doins failed"

        insinto "${GAMES_DATADIR}/${PN}/scenario"
        doins scenario/* || die "doins failed"

        insinto "${GAMES_DATADIR}/${PN}/scripts"
        doins scripts/* || die "doins failed"

	doicon media/openttd.*.png

	if use timidity || use pmidi || use alsa; then
		make_desktop_entry "openttd -m extmidi" "OpenTTD" openttd.64.png
	else
		make_desktop_entry openttd "OpenTTD" openttd.64.png
	fi
	dodoc readme.txt changelog.txt docs/Manual.txt docs/console.txt \
		  docs/multiplayer.txt
	doman docs/openttd.6
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	echo
	einfo "In order to play, you must copy the following 6 files from "
	einfo "the *WINDOWS* version of TTD to ${GAMES_DATADIR}/${PN}/data/"
	echo
	einfo "sample.cat trg1r.grf trgcr.grf trghr.grf trgir.grf trgtr.grf"
	echo
	einfo "There are some scenarios installed "
	einfo "to ${GAMES_DATADIR}/${PN}/scenario"
	einfo "you can use them by copying or symlinking them to"
	einfo "~/.openttd/scenario"
	echo
	einfo "you can do so by running "
	einfo "mkdir ~/.openttd"
	einfo "mkdir ~/.openttd/scenario"
	einfo "ln -s /usr/share/games/openttd/scenario/* ~/.openttd/scenario/"
	echo
	if use timidity || use pmidi || use alsa; then
		einfo "If you want music, you must copy the gm/ directory"
		einfo "to ${GAMES_DATADIR}/${PN}/"
		echo
		einfo "You can enable midi by running"
		einfo "${GAMES_BINDIR}/openttd -m extmidi"
		echo
		if use timidity; then	
			einfo "You've emerge with 'timidity' USE flag:"
			einfo "You also need soundfonts for timidity, if you don't"
			einfo "know what that is, do:"
			echo
			einfo "emerge media-sound/timidity-eawpatches"
		else
			if use pmidi; then
				echo
			else
				einfo "You've emerge with 'aplaymidi' for playing midi"
				einfo "You have to set environment variable ALSA_OUTPUT_PORTS"
				einfo "You can see available ports with 'aplaymidi -l'"
			fi
		fi
			
	echo
	fi
}