Ebuild for media-video/tovid

tovid-0.18b.ebuild (text/plain), 1.91 KB, created by Thomas Loeber on 2005-03-14 09:26:48 UTC

# Copyright 2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit eutils

DESCRIPTION="Video conversion and DVD authoring tools"
HOMEPAGE="http://tovid.sourceforge.net/"

IUSE="cdr gtk vcd"

RDEPEND="gtk? (	>=x11-libs/wxGTK-2.4.2-r2
		dev-python/wxpython )
	media-video/mplayer
	media-video/mjpegtools
	media-video/ffmpeg
	media-video/transcode
	media-sound/normalize
	>=media-gfx/imagemagick-6.0
	media-sound/sox
	>=media-video/dvdauthor-0.6.0
	vcd? (media-video/vcdimager)
	cdr? (	media-libs/libdvdcss
		media-video/lsdvd
		virtual/cdrtools )"

KEYWORDS="~x86 ~amd64"
LICENSE="GPL-2"
RESTRICT="nomirror"
SLOT="0"

MY_P=${P/-/_}
SRC_URI="mirror://sourceforge/tovid/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if ! $(which mencoder &>/dev/null); then
		eerror "Could not find 'mencoder'."
		eerror "Please merge mplayer with useflag 'encode'."
		die
	fi
}

src_compile() {
	true
}

src_install() {
	into /usr
	dobin idvid makemenu makeslides makexml postproc tovid tovid-batch tovid-interactive
	if useq gtk; then
		dobin tovidgui.py
	fi
	if useq cdr; then
		dobin dvrequant
	fi
	dodoc README
}

pkg_postinst() {
	einfo ""
	einfo "List of suite components:"
	if useq cdr; then
		einfo "   dvrequant:   Shrinks and re-authors titles from existing DVDs"
	fi
	einfo "   idvid:       Identifies video format, resolution, and length"
	einfo "   makemenu:    Creates (S)VCD/DVD menus"
	einfo "   makeslides:  Creates mpeg still slides for (S)VCD"
	einfo "   makexml:     Creates XML specification for an (S)VCD or DVD navigation hierarchy"
	einfo "   postproc:    Adjusts A/V sync and does shrinking of encoded video"
	einfo "   tovid:       Converts video to (S)VCD or DVD mpeg format"
	if useq gtk; then
		einfo "   tovidgui.py: A graphical interface for converting video"
	fi
	einfo ""
	einfo "Please check out the tovid documentation on the web:"
	einfo "   http://tovid.sourceforge.net/"
	einfo ""
}