ebuild for muttng-20050304

muttng-20050304.ebuild (text/plain), 2.65 KB, created by Christopher Korn on 2005-03-04 02:04:03 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="mutt-ng is the next generation of mutt."
HOMEPAGE="http://mutt-ng.berlios.de/"
SRC_URI="http://mutt-ng.berlios.de/snapshots/${P}.tar.gz"
RESTRICT=nomirror
IUSE="crypt debug imap mbox nls nntp slang ssl"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="-* ~x86 ~amd64 ~ppc"
RDEPEND="nls? ( sys-devel/gettext )
	>=sys-libs/ncurses-5.2
	ssl? ( >=dev-libs/openssl-0.9.6 )
	slang? ( >=sys-libs/slang-1.4.2 )"
DEPEND="${RDEPEND}
	net-mail/mailbase
	!mail-client/mutt"


src_unpack() {
	unpack ${P}.tar.gz && cd ${S} || die "unpacking failed"
	
	aclocal -I m4					|| die "aclocal failed"
	autoheader						|| die "autoheader failed"
	make -C m4 -f Makefile.am.in	|| die "make in m4 failed"
	automake --foreign				|| die "automake failed"
	WANT_AUTOCONF=2.5 autoconf		|| die "autoconf failed"
}

pkg_setup() {
    einfo "NOTE: muttng is still under heavy development."
    einfo "If you find a bug please report at http://bugs.gentoo.org"
	if ! use imap; then
		echo 
		einfo 
		einfo "NOTE: USE Variable 'imap' is not set. You don't have any IMAP support"
		einfo
		echo 
	fi
}

src_compile() {	
	local myconf="
		$(use_enable nls) \
		$(use_with ssl) \
		$(use_enable imap) \
		$(use_enable crypt pgp) \
		--sysconfdir=/etc/muttng \
		--with-docdir=/usr/share/doc/muttng-${PVR} \
		--with-regex --enable-pop \
		--disable-fcntl --enable-flock --enable-external-dotlock"

		if use slang; then
			myconf="${myconf} --with-slang"
			ewarn "To use a transparend background merge muttng with USE=-slang"
		else
			myconf="${myconf} --with-curses"
		fi

		if use mbox; then
			myconf="${myconf} --with-maildir=/var/spool/mail"
		else
			myconf="${myconf} --with-homespool=Maildir"
		fi

		myconf="${myconf} $(use_enable imap imap-edit-threads)"
		myconf="${myconf} --enable-compressed"
		myconf="${myconf} $(use_enable nntp)"
		myconf="${myconf} --enable-hcache"

		econf ${myconf}
		make || die "make failed (myconf=${myconf})"
}

src_install() {
	make DESTDIR=${D} install || die "install failed"
	find ${D}/usr/share/doc -type f | grep -v "html\|manual" | xargs gzip
	if use mbox; then
		insinto /etc/muttng
		newins ${FILESDIR}/Muttngrc.mbox Muttngrc
	else
		insinto /etc/muttng
		doins ${FILESDIR}/Muttngrc
	fi

	dodoc BEWARE COPYRIGHT ChangeLog NEWS OPS* PATCHES README* TODO VERSION
}

pkg_postinst() {
	einfo "The USE variable 'imap' is not set by default on most architectures."
	einfo "To enable imap support in mutt, make sure you have USE=imap"
	einfo
    einfo "NOTE: muttng is still under heavy development."
    einfo "If you find a bug please report at http://bugs.gentoo.org"
}