cjk-lyx-1.3.5.ebuild (modified)

cjk-lyx-1.3.5.ebuild (text/plain), 3.79 KB, created by MATSUI Tetsushi on 2005-02-26 17:35:16 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvs/cvsroot/gentoo/portage/app-office/cjk-lyx/cjk-lyx-1.3.5.ebuild,v 1.1 2004/11/08 21:07:03 glc Exp $

inherit kde-functions eutils libtool

MY_PN="CJK-LyX"
DESCRIPTION="a multibyte version of LyX"
HOMEPAGE="http://cellular.phys.pusan.ac.kr/cjk.html"
SRC_URI="ftp://ftp.lyx.org/pub/lyx/stable/lyx-${PV}.tar.bz2
	http://movementarian.org/latex-xft-fonts-0.1.tar.gz
	http://www.math.tau.ac.il/~dekelts/lyx/files/hebrew.bind
	http://www.math.tau.ac.il/~dekelts/lyx/files/preferences
	qt? ( ftp://cellular.phys.pusan.ac.kr/CJK-LyX/xforms/${MY_PN}-qt-${PV}-1.patch )
	!qt? ( ftp://cellular.phys.pusan.ac.kr/CJK-LyX/xforms/${MY_PN}-xforms-${PV}-1.patch )"


LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~amd64"
IUSE="nls cups qt debug gnome spell"

### Remove this before committing to CVS ###
RESTRICT="nomirror"
### Remove this before committing to CVS ###

# these dependencies need looking at.
# does lyx only need qt to compile but not run ?
# I'll look into it <[e-mail]>
DEPEND="virtual/x11
	virtual/tetex
    !app-office/lyx
	>=dev-lang/perl-5
	>=sys-devel/autoconf-2.58
	nls? ( sys-devel/gettext )
	spell? ( app-text/aiksaurus )
	qt? ( >=x11-libs/qt-3 ) !qt? ( =x11-libs/xforms-1* )"

RDEPEND="${DEPEND}
	virtual/ghostscript
	virtual/pdfviewer
	virtual/psviewer
	virtual/aspell-dict
	dev-tex/latex2html
	media-gfx/imagemagick
	cups? ( virtual/lpr )
	app-text/rcs
	dev-util/cvs
	app-text/sgmltools-lite
	app-text/noweb
	dev-tex/chktex"

S=${WORKDIR}/lyx-${PV}
src_unpack() {
	unpack lyx-${PV}.tar.bz2
	unpack latex-xft-fonts-0.1.tar.gz
	cd ${S}
	epatch ${FILESDIR}/lyx-1.3.2-nomktex.patch
	epatch ${FILESDIR}/lyx-1.3.3-configure-diff
	epatch ${FILESDIR}/lyx-1.3.5-boost.patch
	if use qt; then
		epatch ${DISTDIR}/${MY_PN}-qt-${PV}-1.patch
	else
		epatch ${DISTDIR}/${MY_PN}-xforms-${PV}-1.patch
	fi

	elibtoolize || die
}

src_compile() {
	local myconf=""
	if use qt ; then
		set-qtdir 3
		myconf="$myconf --with-frontend=qt --with-qt-dir=${QTDIR}"
	else
		myconf="$myconf --with-frontend=xforms"
	fi

	export WANT_AUTOCONF=2.5

	local flags="${CFLAGS}"
	unset CFLAGS
	unset CXXFLAGS
	econf \
		$(use_enable nls) \
		$(use_enable debug) \
		${myconf} \
		--enable-optimization="$flags" \
		|| die
	# bug 57479
	emake || die "emake failed"

}

src_install() {
	einstall || die
	dodoc README* UPGRADING INSTALL* ChangeLog NEWS COPYING \
		ANNOUNCE ABOUT-NLS ${DISTDIR}/preferences
	insinto /usr/share/lyx/bind
	doins ${DISTDIR}/hebrew.bind

	# gnome menu entry
	if use gnome; then
		insinto /usr/share/applications
		doins ${FILESDIR}/lyx.desktop
	fi

	# install the latex-xft fonts, which should fix
	# the problems outlined in bug #15629
	# <[e-mail]>
	cd ${WORKDIR}/latex-xft-fonts-0.1
	make DESTDIR=${D} install || die "Font installation failed"

	mkfontscale ${D}/usr/share/fonts/latex-xft-fonts
	mkfontdir -e /usr/share/fonts/encodings \
		-e /usr/share/fonts/encodings/large \
		-e /usr/X11R6/$(get_libdir)/X11/fonts/encodings \
		${D}/usr/share/fonts/latex-xft-fonts
	HOME=/root fc-cache -f ${D}/usr/share/fonts/latex-xft-fonts
}

pkg_postinst() {

	einfo ""
	einfo "================"
	einfo ""
	einfo "How to use Hebrew in LyX:"
	einfo "1. emerge app-text/ivritex."
	einfo "2. unzip /usr/share/doc/${P}/preferences.gz into ~/.lyx/preferences"
	einfo "or, read http://www.math.tau.ac.il/~dekelts/lyx/instructions2.html"
	einfo "for instructions on using lyx's own preferences dialog to equal effect."
	einfo "3. use lyx's qt interface (compile with USE=qt) for maximum effect."
	einfo ""

	if ! use qt ; then
	einfo "================"
	einfo ""
	einfo "If you have a multi-head setup not using xinerama you can only use lyx"
	einfo "on the 2nd head if not using qt (maybe due to a xforms bug). See bug #40392."
	einfo ""
	fi
}