# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-rpg/eternal-lands/eternal-lands-1.0.0.ebuild,v 1.4 2004/11/30 03:51:31 kingtaco Exp $

#
# USE-flags:
#
# doc - Generates documentation for the client source using Doxygen.
#
# music - Installs the optional music files (27MB)
#
# mapeditor - Installs the map editor and an introduction to using this tool
# - since it currently requires gtk+ 1.2 it was made optional.
#

inherit games

DESCRIPTION="An online MMORPG written in C and SDL"
HOMEPAGE="http://www.eternal-lands.com"
TMP_PV=${PV%_p*}
SRC_URI="http://el.tfm.ro/el_${TMP_PV//.}.zip
	ftp://ftp.berlios.de/pub/elc/elc_${PV//.}.tgz
	mapeditor? ( ftp://ftp.berlios.de/pub/elc/mapedit_${PV//.}.tgz )
	music? ( http://el.tfm.ro/music.zip )"

LICENSE="eternal_lands"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="doc music mapeditor amd64"

RDEPEND="virtual/x11
	virtual/opengl
	>=media-libs/libsdl-1.2.5
	>=media-libs/sdl-net-1.2.5
	>media-libs/openal-20020127
	media-libs/libvorbis
	>=dev-libs/libxml2-2.6.7
	doc? ( >=app-doc/doxygen-1.3.8
		>=media-gfx/graphviz-1.10)
	mapeditor? ( <x11-libs/gtk+-1.3 )"

DEPEND="${RDEPEND}
	app-arch/unzip"

OPTIONS="OPTIONS=-DDATA_DIR="\\\\\"${GAMES_DATADIR}/${PN}/\\\\\"" "

S_CLIENT="${WORKDIR}/elc"
S_MAPEDITOR="${WORKDIR}/map_editor"

pkg_setup() {
	if ! use music; then
		echo
		einfo "To get music in the game, add:"
		einfo "games-rpg/eternal-lands music"
		einfo "to /etc/portage/package.use"
		echo
	fi
	if ! use mapeditor; then
		echo
		einfo "If you wish to use the map editor"
		einfo "you have to add it to the use flags"
		einfo "by adding:"
		einfo "games-rpg/eternal-lands mapeditor"
		einfo "to /etc/portage/package.use"
		echo
	fi
}

# Currently this package doesn't have a configure script using autoconf or the
# like, but it is planned to get in 1.0.2
src_unpack() {
	unpack ${A}
	use amd64 && OPTIONS="${OPTIONS} -DX86_64"
	cd "${S_CLIENT}"
	sed \
		-e "s@CFLAGS=\$(PLATFORM) -Wall -O -Werror -ggdb -pipe @CFLAGS=${CFLAGS} @g" \
		-e "s@OPTIONS=@${OPTIONS} @g" \
		Makefile.linux > Makefile \
		|| die "sed failed"
	sed \
		-e 's/#browser/browser/g' \
		-e 's/browser = mozilla/#browser = mozilla/g' \
		-e "s@#data_dir = /usr/local/games/el/@#data_dir = ${GAMES_DATADIR}/${PN}/@g" \
		el.ini > ../el.ini \
		|| die "sed failed"
	if use mapeditor; then
		cd ${S_MAPEDITOR}
		sed \
			-e "s@CFLAGS=@CFLAGS=${CFLAGS} @g" \
			-e "s@OPTIONS=@${OPTIONS} @g" \
			Makefile.linux > Makefile \
			|| die "sed failed"
		sed \
			-e "s@#data_dir = /usr/local/games/el/@#data_dir = ${GAMES_DATADIR}/${PN}/@g" \
			mapedit.ini > ../mapedit.ini \
			|| die "sed failed"
	fi
	cd ${WORKDIR}
	cp license.txt EULA || die "cp failed"
	cp changes.txt ChangeLog || die "cp failed"
}

src_compile() {
	cd ${S_CLIENT}
	emake || die "emake failed"
	cp el.x86.linux.bin ../el.x86.linux.bin || die "cp failed"
	if use doc; then 
		emake docs || die "Failed to create documentation, try with USE=-docs"
		mv ./docs/html/ ../client || die "Failed to move documentation directory"
	fi
	if use mapeditor; then
		cd ${S_MAPEDITOR}
		emake || die "emake failed"
		cp mapedit.x86.linux.bin ../mapedit.x86.linux.bin || die "cp failed"
	fi
}

src_install () {
	cd "${WORKDIR}"
	insinto "${GAMES_DATADIR}/${PN}"
	
	newgamesbin el.x86.linux.bin el
	use mapeditor && newgamesbin mapedit.x86.linux.bin el-mapedit
	
	dodoc ChangeLog EULA
	doins *.ini *.lst el_icon.png icon.bmp global_filters.txt local_ignores.txt \
		e3dlist.txt || die "Files failed to be installed"
	cp -R 2dobjects 3dobjects languages maps md2 particles sound textures tiles \
		"${D}/${GAMES_DATADIR}/${PN}" \
		|| die "copy failed"
	
	if use music; then
		cp -R music "${D}/${GAMES_DATADIR}/${PN}" || die "copy music failed"
	fi
	
	prepgamesdirs

#Documentation

	if use doc; then
		cp -r ${WORKDIR}/client/ ${D}/usr/share/doc/${PF}/html/ || die "Failed to copy client documentation"
	fi
	if use mapeditor; then
		dohtml ${WORKDIR}/mapeditor.html || die "Failed to copy map editor documentation"
		cp -r ${WORKDIR}/mapeditor/ ${D}/usr/share/doc/${PF}/html/ || die "Failed to copy map editor documentation"
	fi
}

pkg_postinst() {
	games_pkg_postinst
	echo
	einfo "To run the game: el"
	einfo "Copy ${GAMES_DATADIR}/${PN}/el.ini to ~/.elc/"
	einfo "to make per-user changes."
	echo
	if use mapeditor; then
		einfo "To use the map editor: el-mapedit"
		einfo "Copy ${GAMES_DATADIR}/${PN}/mapedit.ini to ~/.elc/"
		einfo "to make per-user changes."
		echo
		einfo "To read an introduction to the map editor, read"
		einfo "/usr/share/doc/${PF}/html/mapeditor.html"
		echo
	fi
	if use doc; then
		einfo "The documentation for the client source can be found"
		einfo "in /usr/share/doc/${PF}/html/client"
		echo
	fi
}