acx100-0.2.0_pre8.ebuild

acx100-0.2.0_pre8.ebuild (text/plain), 1.20 KB, created by Stefan Schweizer (RETIRED) on 2005-01-24 10:26:51 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit linux-mod

FIX_VERSION=44
FW_VERSION=307

DESCRIPTION="Driver for the ACX100 and ACX111 wireless chipset (CardBus and USB)"

HOMEPAGE="http://acx100.sourceforge.net/"
SRC_URI="http://lisas.de/~andi/${PN}/${P/_/}_plus_fixes_${FIX_VERSION}.tar.bz2
	http://www.houseofcraig.net/acx_firmware.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="nomirror"

RDEPEND=">=sys-apps/hotplug-20040923
        net-wireless/wireless-tools"

S=${WORKDIR}/${P/_/}_plus_fixes_${FIX_VERSION}
MODULE_NAMES="acx_pci(net:${S}/src) acx_usb(net:${S}/src)"
CONFIG_CHECK="NET_RADIO FW_LOADER"
BUILD_PARAMS="KERNELVER=${KV_FULL} KERNELDIR=${KV_DIR} KERNEL_BUILD=${KV_DIR}"
BUILD_TARGETS="all"

src_compile() {
	sed -si "s:KERNEL_VER=\`uname -r\`:KERNEL_VER=${KV_FULL}:" Configure
	sed -si "s:KERNEL_BUILD=/lib/modules/\$KERNEL_VER/build:KERNEL_BUILD=${KV_DIR}:" Configure
	./Configure
	linux-mod_src_compile
}

src_install() {
	linux-mod_src_install
	
	dodoc README TODO ChangeLog doc/*

	insinto /lib/firmware
	doins ${WORKDIR}/usr/share/acx/*
	dosym /lib/firmware /usr/share/acx100
	dosym /lib/firmware /usr/share/acx
}