net-print/bjfilterpixus560i/bjfilterpixus560i-2.4.ebuild

bjfilterpixus560i-2.4.ebuild (text/plain), 3.00 KB, created by tuXXer on 2005-01-02 14:50:29 UTC

# Copyright 1999-2005 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PV="-${PV}-0"
MY_P1="bjcups${MY_PV}"
MY_P2="bjfilter${MY_PV}"
MY_P3="bjcupsmon${MY_PV}"
MY_P4="printui${MY_PV}"
MY_P5="stsmon${MY_PV}"
MY_EXT=".tar.gz"
S1="${WORKDIR}/${MY_P1}"
S2="${WORKDIR}/${MY_P2}"
S3="${WORKDIR}/${MY_P3/-0/}"
S4="${WORKDIR}/${MY_P4}"
S5="${WORKDIR}/${MY_P5/-0/}"

DESCRIPTION="Libraries for Canon Pixus 560i printers"
HOMEPAGE="http://canon.jp/"
SRC_PREFIX="ftp://download.canon.jp/pub/driver/bj/linux"
SRC_URI="${SRC_PREFIX}/${MY_P1}${MY_EXT} ${SRC_PREFIX}/${MY_P2}${MY_EXT} ${SRC_PREFIX}/${MY_P3}${MY_EXT} ${SRC_PREFIX}/${MY_P4}${MY_EXT} ${SRC_PREFIX}/${MY_P5}${MY_EXT}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE=""

RDEPEND=">=app-text/ghostscript-5.50
	>=dev-libs/libxml-1.8
	>=dev-libs/popt-1.6
	<gnome-base/libglade-2.0
	>=media-libs/libpng-1.0.9
	>=media-libs/tiff-3.4
	>=net-print/cups-1.1.14
	=net-print/pixus560i-libs-2.4
	=x11-libs/gtk+-1.2*"
DEPEND="${RDEPEND}
	>=sys-devel/autoconf-2.5
	>=sys-devel/automake-1.4
	>=sys-libs/glibc-2.0"

src_unpack() {
	cd ${WORKDIR} || die "Could not change to work directory."

	# Unpack packages
	unpack ${A} || die "Could not unpack packages."

	# Applying gentoo patches
	for PATCH in ${MY_P1} ${MY_P2} ${MY_P3} ${MY_P4} ${MY_P5}; do
		epatch ${FILESDIR}/${PATCH}_gentoo.patch || die "Could not apply patch."
	done

	# Applying D to make files
	cd ${S1}
	for MAKEFILE in $(find -name "Makefile") ${S3}/backend/Makefile.am; do
		sed -i -e "s:%%D%%:${D}:g" ${MAKEFILE}
	done
}

src_compile() {
	# Generate configuration files
	export WANT_AUTOCONF=2.5 WANT_AUTOMAKE=1.4

	cd ${S3}
	./autogen.sh \
		--host=${CHOST} \
		--prefix=/usr \
		--infodir=/usr/share/info \
		--mandir=/usr/share/man || die "Could not configure package."
	
	for DIR in ${S2} ${S4} ${S5}; do
		cd ${DIR}
		./autogen.sh \
			--program-suffix=pixus560i \
			--host=${CHOST} \
			--prefix=/usr \
			--infodir=/usr/share/info \
			--mandir=/usr/share/man || die "Could not configure package."
	done

	unset WANT_AUTOCONF WANT_AUTOMAKE

	# Compile packages
	for DIR in ${S1}/libs ${S1} ${S2} ${S3} ${S4} ${S5}; do
		cd ${DIR}
		emake || die "Could not compile package."
	done
}

src_install() {
	# Create directories
	dodir /usr/bin /usr/lib/cups/filter /usr/share/cups/model

	# Install packages
	for DIR in ${S1} ${S2} ${S3} ${S4} ${S5}; do
		cd ${DIR}
		einstall || die "Could not install package."
	done

	# Install docs
	docinto bjcups
	dodoc ${S1}/ChangeLog ${S1}/COPYING ${S1}/INSTALL ${S1}/LICENSE ${S1}/README

	docinto bjfilter
	dodoc ${S2}/AUTHORS ${S2}/ChangeLog ${S2}/COPYING ${S2}/INSTALL ${S2}/LICENSE ${S2}/NEWS ${S2}/README

	docinto bjcupsmon
	dodoc ${S3}/ChangeLog ${S3}/COPYING ${S3}/INSTALL ${S3}/LICENSE ${S3}/README

	docinto printui
	dodoc ${S4}/AUTHORS ${S4}/ChangeLog ${S4}/COPYING ${S4}/INSTALL ${S4}/LICENSE ${S4}/NEWS ${S4}/README

	docinto stsmon
	dodoc ${S5}/AUTHORS ${S5}/ChangeLog ${S5}/COPYING ${S5}/INSTALL ${S5}/LICENSE ${S5}/NEWS ${S5}/README		
}