astroseries-1.2_beta1.ebuild

astroseries-1.2_beta1.ebuild (text/plain), 1.12 KB, created by Martti Rannanjärvi on 2004-12-30 09:05:46 UTC

# Copyright 2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

MY_PV=${PV/./p}; MY_PV=${MY_PV/_}

DESCRIPTION="Astroseries is a futuristic RTS game for the Stratagus game engine"
HOMEPAGE="http://www.astroseries.com/"
SRC_URI="mirror://sourceforge/${PN}/astrov${MY_PV}.zip
	mirror://sourceforge/${PN}/ezpatch1.zip"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND="=games-engines/stratagus-2.1*"
DEPEND=""

S="${WORKDIR}/Astroseries"

DIR="${GAMES_DATADIR}/stratagus/${PN}"

src_unpack() {
	unpack ${A}

	# This update from ezpatch1.zip
	mv patch1/upgrade.lua Astroseries/scripts/human/

	# Clean some stuff unlikely to be used
	find -name 'Thumbs.db' -exec rm "{}" \;
	find -name 'WS_FTP.LOG' -exec rm "{}" \;
	find -name '*.rej' -exec rm "{}" \;
	
	# Make wrapper
	cat > "${S}/astroseries" <<-EOF
	#!/bin/sh
	exec ${GAMES_BINDIR}/stratagus -d ${DIR} "\$@"
	EOF
}

src_install() {
	dodir ${DIR}
	mv data/* scripts "${D}/${DIR}" || die "Copying media failed"
	dogamesbin astroseries || die "dogamesbin failed"
	dodoc notes.txt
	dohtml readme.html
	prepgamesdirs
}