# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/multisync/multisync-0.82.ebuild,v 1.8 2004/10/04 18:54:55 brix Exp $

ECVS_SERVER="cvs.sourceforge.net:/cvsroot/multisync"
ECVS_MODULE="multisync"
ECVS_USER="anonymous"
ECVS_CVS_OPTIONS="-dP"

inherit cvs

S=${WORKDIR}/${ECVS_MODULE}

inherit eutils

DESCRIPTION="Client to sync apps with WinCE or mobile devices"
HOMEPAGE="http://multisync.sourceforge.net/"
SRC_URI="http://multisync.sourceforge.net/files/multisync-cvs-snapshot.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ~amd64 ~ppc"
IUSE="evo evo2 irmc opie ldap bluetooth syncml kde palm csa gnokii"
# evo   - evolution plugin
# irmc  - bluetooth/irmc/irda plugin ( local )
# opie  - opie plugin                ( local )
# ldap  - ldap plugin - experimental

DEPEND=">=gnome-base/libbonobo-2.2
	>=gnome-base/libgnomeui-2.2
	>=gnome-base/libgnome-2.2
	>=dev-libs/glib-2
	>=gnome-base/gconf-2
	>=gnome-base/gnome-vfs-2.2
	>=gnome-base/orbit-2.8.2
	>=dev-libs/openssl-0.9.6j
	evo?  ( >=mail-client/evolution-1.4* )
	evo2?  ( >=mail-client/evolution-2* )
	irmc? ( >=net-wireless/irda-utils-0.9.15
		>=dev-libs/openobex-1
		bluetooth? ( >=net-wireless/bluez-libs-2.7
			         >=net-wireless/bluez-utils-2.7 )
	)
	opie? ( >=net-misc/curl-7.10.5 )
	ldap? ( >=net-nds/openldap-2.0.27
		>=dev-libs/cyrus-sasl-2.1.4 )
	kde? ( >=kde-base/kdepim-3.2* )
	gnokii? ( >=net-dialup/gnokii-6* )
	palm? ( app-pda/gnome-pilot )
	syncml? ( >=net-libs/wbxml2-0.9.0 )"

make_plugin_list() {
	export PLUGINS="backup_plugin"
	use irmc && PLUGINS="${PLUGINS} irmc_sync"
	use evo && PLUGINS="${PLUGINS} evolution_sync"
	use evo2 && PLUGINS="${PLUGINS} evolution2_sync"
	use opie && PLUGINS="${PLUGINS} opie_sync"
	use palm && PLUGINS="${PLUGINS} palm_sync"
	use gnokii && PLUGINS="${PLUGINS} gnokii_sync"
	#use ldap && PLUGINS="${PLUGINS} ldap_plugin"
	use ldap && einfo "The ldap plugin seems to be not finished yet.  Disabling this plugin."
	use syncml && PLUGINS="${PLUGINS} syncml_plugin"
	#use kde && PLUGINS="${PLUGINS} kdepim_plugin"
	use kde && einfo "There is a nasty sandbox violation in the kdepim plugin.  Disabling this plugin."
	use csa && PLUGINS="${PLUGINS} csa_plugin"
}

src_unpack() {
	unpack ${A}
	cd ${S}
#
#	# Fix to use evolution-2.0 filepath (can coexist with 1.4)
#	#epatch ${FILESDIR}/${PN}-0.82-evolution2.patch
#	version=`cat configure | grep "VERSION=" | grep -v PACKAGE_VERSION | sed -e 's/VERSION=//g' | sed -e 's/ //g'`
#	srcdir=`pwd`
}

src_compile() {
	# Stick the AUTOMAKE and AUTOCONF versions
	export WANT_AUTOMAKE=1.7
	export WANT_AUTOCONF=2.5

	make_plugin_list

	einfo "Building Multisync with these plugins:"
	for plugin_dir in ${PLUGINS}
	do
		einfo "      ${plugin_dir}"
	done

	cd ${S}
	./autogen.sh --prefix=/usr
	make || die "Multisync make failed"

	cd ${S}/plugins
	for plugin_dir in ${PLUGINS}
	do
		einfo "Building Multisync plugin: ${plugin_dir}"
		cd ${S}/plugins/${plugin_dir}
		./autogen.sh --prefix=/usr
		make || die "${plugin_dir} make failed!"
	done
}

src_install() {
	make_plugin_list
	make install DESTDIR=${D} || die "Multisync install failed!"
	for plugin_dir in ${PLUGINS}
	do
		cd ${S}/plugins/${plugin_dir}
		make install DESTDIR=${D} || die "${plugin_dir} install failed!"
	done
}