# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/pcsx2/pcsx2-0.6.ebuild,v 1.2 2004/06/24 22:32:22 agriffis Exp $

inherit eutils games

DESCRIPTION="Playstation2 emulator"
HOMEPAGE="http://www.pcsx2.net/"
SRC_URI="http://www.pcsx2.net/download/${PV}release/pcsx2_${PV}src.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ~amd64"
IUSE="x86"

RDEPEND="virtual/x11
	=x11-libs/gtk+-1*
	|| (
		>=games-emulation/ps2emu-cddvdlinuz-0.3-r1
		>=games-emulation/ps2emu-cdvdiso-0.3
	)
	>=games-emulation/ps2emu-gssoft-0.61
	>=games-emulation/ps2emu-padxwin-0.5
	>=games-emulation/ps2emu-spu2null-0.21
	>=games-emulation/ps2emu-dev9null-0.2"
DEPEND="${RDEPEND}
	dev-lang/nasm"

S="${WORKDIR}/pcsx2_${PV}src"

src_unpack() {
	unpack ${A}
	cd ${S}
	find . -name CVS -type d -print0 | xargs -0 rm -rf
	epatch "${FILESDIR}/pcsx2-0.6-cpucheck.patch"
}

src_compile() {
	if use x86; then
		einfo 'Building x86 just-in-time recompiler'
		cd "${S}/ix86-32/GoldRec"
		emake OPTIMIZE="${CFLAGS}" || die "goldrec building failed"
	else
		einfo 'No just-in-time recompiler available for this architecture'
	fi
	einfo 'Building emulator'
	cd "${S}/Linux"
	if use x86; then
		emake OPTIMIZE="${CFLAGS}" || die "linux building failed"
	else
		emake OPTIMIZE="${CFLAGS}" CPU="$(uname -m)" CPUTYPE="$(uname -m -p)" || die "linux building failed"
	fi
}

src_install() {
	newgamesbin Linux/pcsx2 pcsx2.bin || die "newgamesbin failed"
	dogamesbin "${FILESDIR}/pcsx2" || die "dogamesbin failed"
	dodir "${GAMES_LIBDIR}/ps2emu/Langs"
	cp -r Intl/Langs/* "${D}/${GAMES_LIBDIR}/ps2emu/Langs/" || die "cp failed"
	dodoc Docs/*.txt
	prepgamesdirs
}