# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:

inherit eutils

DESCRIPTION="IrDA Utilities, tools for IrDA communication"
HOMEPAGE="http://irda.sourceforge.net/"
SRC_URI="mirror://sourceforge/irda/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~amd64"
IUSE="gtk"

DEPEND="virtual/libc
	>=dev-libs/glib-2
	gtk? ( =x11-libs/gtk+-1.2* )"

src_unpack() {
	unpack ${A}

	cd ${S}
	epatch ${FILESDIR}/${PN}-gtk+2.patch
	epatch ${FILESDIR}/${PN}-includes.patch
	epatch ${FILESDIR}/${PN}-makefiles.patch
	epatch ${FILESDIR}/${PN}-gcc3.4-fix.patch
	epatch ${FILESDIR}/${PN}-tekram-ppc-buildfix.patch
	epatch ${FILESDIR}/${PN}-rh1.patch
	epatch ${FILESDIR}/${PN}-rootonly.patch
}

src_compile() {
	export WANT_AUTOMAKE=1.4

	if use x86; then
		cd ${S}/findchip
		emake GCFLAGS="${CFLAGS}" || die "Making findchip failed"

		if use gtk; then
			emake gfindchip || die "Making gfindchip failed"
		fi
	fi

	cd ${S}/irdadump
	libtoolize
	aclocal
	autoconf
	autoheader
	econf
	emake || die "Making irdadump failed"

	for i in irattach irdaping irsockets psion tekram
	do
		cd ${S}/${i}
		emake GCFLAGS="${CFLAGS}" || die "Making ${i} failed"
	done
}

src_install () {
	if use x86; then
		dosbin findchip/findchip
		if use gtk; then
			dosbin findchip/gfindchip
		fi
	fi

	dosbin irattach/irattach
	dosbin irattach/dongle_attach
	dosbin irdaping/irdaping
	dosbin tekram/irkbd
	dosbin irdadump/shell/irdadump

	into /usr
	dobin irsockets/irdaspray
	dobin irsockets/ias_query
	dobin irsockets/irprintf
	dobin irsockets/irprintfx
	dobin irsockets/irscanf
	dobin irsockets/recv_ultra
	dobin irsockets/send_ultra
	dobin psion/irpsion5

	# install README's into /usr/share/doc
	for i in *
	do
		if [ -d $i -a $i != "man" ]; then
			if [ -f $i/README ]; then
				cp $i/README README.$i
				dodoc README.$i
				rm README.$i
			fi
		fi
	done
	
	# man files
	cd ${S}/man
	for i in `ls *.gz`
	do
		doman $i
	done

	insinto /etc/conf.d ; newins ${FILESDIR}/irda.conf irda
	insinto /etc/init.d ; insopts -m0755 ; newins ${FILESDIR}/irda.rc irda
}