# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Ziproxy is forwarding, non-caching, compressing web proxy server."
HOMEPAGE="http://ziproxy.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~x86"
IUSE="jp2"
DEPEND="sys-libs/zlib
	dev-libs/confuse
	media-libs/giflib
	media-libs/libungif
	media-libs/libpng
	media-libs/jpeg
	jp2? ( media-libs/jasper )"


src_compile() {
	local myconf="--enable-shared-confuse --with-cfgfile=/etc/ziproxy.conf"
	use jp2 && myconf="$myconf --with-jasper"
	econf $myconf || die "econf failed"
	emake || die "emake failed"
	# fix sample xinetd config filee
	sed -i -e "s|/home/juro/bin/|/usr/bin/|g" -e "s|/home/juro/ziproxy/|/etc/|g" \
		-e "s|disable.*$|disable\t\t\t = yes|g" xinetd/ziproxy
	# fix sample config file
	sed -i -e "s|/home/juro/bin/|/usr/bin/|g" \
		-e "s|^LogFile.*|LogFile = \"/var/log/ziproxy_%j-%Y.log\"|g" ziproxy.conf
	echo >> ziproxy.conf # add line break
}

src_install() {
	einstall || die
	dodoc ChangeLog CREDITS README
	use jp2 && dodoc JPEG2000.txt
	insinto /etc
	doins ziproxy.conf
	insinto /etc/xinetd.d
	doins xinetd/ziproxy
	insinto /etc/conf.d
	newins ${FILESDIR}/ziproxy.confd ziproxy
	exeinto /etc/init.d
	newexe ${FILESDIR}/ziproxy.initd ziproxy
}