texmaker-4.4.1.ebuild

texmaker-4.4.1.ebuild (text/plain), 2.05 KB, created by Ben de Groot (RETIRED) on 2015-01-04 10:50:45 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/texmaker-4.3.ebuild,v 1.1 2014/08/21 07:38:16 jlec Exp $

EAPI=5
inherit eutils qmake-utils readme.gentoo

DESCRIPTION="A nice LaTeX-IDE"
HOMEPAGE="http://www.xm1math.net/texmaker/"
SRC_URI="http://www.xm1math.net/texmaker/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="+qt4 qt5" # qt5 should be made default once it goes stable
REQUIRED_USE="^^ ( qt4 qt5 )"

COMMON_DEPEND="
	app-text/hunspell
	sys-libs/zlib
	x11-libs/libX11
	x11-libs/libXext
	qt4? ( app-text/poppler:=[qt4]
		dev-qt/qtcore:4
		dev-qt/qtgui:4
		dev-qt/qtscript:4
		dev-qt/qtsingleapplication[X,qt4]
		dev-qt/qtwebkit:4 )
	qt5? ( app-text/poppler:=[qt5]
		dev-qt/qtcore:5
		dev-qt/qtconcurrent:5
		dev-qt/qtgui:5
		dev-qt/qtprintsupport:5
		dev-qt/qtscript:5
		dev-qt/qtsingleapplication[X,qt5]
		dev-qt/qtwebkit:5[printsupport]
		dev-qt/qtwidgets:5
		dev-qt/qtxml:5 )"
RDEPEND="${COMMON_DEPEND}
	virtual/latex-base
	app-text/psutils
	app-text/ghostscript-gpl
	media-libs/netpbm
	qt4? ( app-i18n/ibus-qt )"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"

DOCS=( utilities/AUTHORS utilities/CHANGELOG.txt )
HTML_DOCS=( doc/. )

src_prepare() {
	epatch "${FILESDIR}"/${PN}-4.1-unbundle.patch
	find singleapp hunspell -delete || die
	sed -e '/^#include/s:hunspell/::g' \
		-e '/^#include/s:singleapp/::g' \
		-i *.cpp *.h || die

	cat >> ${PN}.pro <<- EOF
	exists(texmakerx_my.pri):include(texmakerx_my.pri)
	EOF

	cp "${FILESDIR}"/texmakerx_my.pri . || die

	DOC_CONTENTS="A user manual with many screenshots is available at:
	${EPREFIX}/usr/share/${PN}/usermanual_en.html"
}

src_configure() {
	local myqmakeargs=(
		${PN}.pro
		PREFIX="${EPREFIX}"/usr
		DESKTOPDIR="${EPREFIX}"/usr/share/applications
		ICONDIR="${EPREFIX}"/usr/share/pixmaps
	)
	use qt4 && eqmake4 ${myqmakeargs[@]}
	use qt5 && eqmake5 ${myqmakeargs[@]}
}

src_install() {
	emake INSTALL_ROOT="${D}" install
	einstalldocs
	readme.gentoo_src_install
}