poedit-1.6.10.ebuild

poedit-1.6.10.ebuild (text/plain), 1.48 KB, created by Nikoli on 2014-11-07 12:25:12 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
WX_GTK_VER="3.0"
PLOCALES="af_ZA am an ar ast az be@latin be bg bn br bs ca ca@valencia ckb co cs da de el en_GB eo es et eu fa_IR fi fr fur ga gl he hi hr hu id is it ja ka kk ko ku ky lt lv mk mn mr ms nb ne nl nn pa pl pt_BR pt ro ru sk sl sq sr sv ta tg th tr tt ug uk ur uz vi wa zh_CN zh_TW"
inherit wxwidgets l10n fdo-mime gnome2-utils

DESCRIPTION="Cross-platform gettext catalogs (.po files) editor"
HOMEPAGE="https://poedit.net"
SRC_URI="https://github.com/vslavik/poedit/releases/download/v${PV}-oss/${P}.tar.gz"

LICENSE="MIT CC-BY-2.5 CC-BY-SA-2.5"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="spell"

RDEPEND="
	dev-libs/boost:=
	x11-libs/wxGTK:${WX_GTK_VER}[X]
	dev-libs/icu:=
	>=dev-cpp/lucene++-3.0.5
	dev-libs/expat:=
	>=sys-libs/db-4.7
	spell? ( app-text/gtkspell:2 )
"

DEPEND="${RDEPEND}
	virtual/pkgconfig
"

src_prepare() {
	my_rm_loc() {
		sed -i -e "/^POEDIT_LINGUAS = /s: ${1}::" locales/Makefile.in || die
		rm "locales/${1}.mo" || die
	}
	# locales/Makefile.in does not have these:
	rm locales/{af,fa}.mo || die
	l10n_find_plocales_changes 'locales' '' '.mo'
	l10n_for_each_disabled_locale_do my_rm_loc
}

src_configure() {
	econf $(use_enable spell spellchecking)
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
}