# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/cvs/cvs-1.11.17.ebuild,v 1.8 2004/06/10 20:17:18 scandium Exp $

inherit eutils flag-o-matic

DESCRIPTION="Concurrent Versions System - source code revision control tools"
HOMEPAGE="http://www.cvshome.org/"

# scandium@gentoo.org (9th June 2004)
# Recently, upstream changed the directory structure for the files.
# The directory numbers in the middle differ for every release/file, so
# unfortunatly they have to be corrected with every new release.
SRC_URI="http://ccvs.cvshome.org/files/documents/19/191/${P}.tar.bz2
	doc? ( http://ccvs.cvshome.org/files/documents/19/199/cederqvist-${PV}.html.tar.bz2
		http://ccvs.cvshome.org/files/documents/19/197/cederqvist-${PV}.pdf
		http://ccvs.cvshome.org/files/documents/19/196/cederqvist-${PV}.ps )"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="x86 ppc sparc mips alpha arm hppa amd64 ia64 ~ppc64 ~s390"

IUSE="crypt cvs-rootcommit doc emacs kerberos"

DEPEND="virtual/glibc
	>=sys-libs/ncurses-5.1
	>=sys-libs/zlib-1.1.4
	kerberos? ( >=app-crypt/mit-krb5-1.3 )"

src_compile() {
	use alpha && append-flags -fPIC

	local myconf
	myconf="$(use_enable crypt encryption)"
	myconf="${myconf} $(use_enable cvs-rootcommit rootcommit)"
	myconf="${myconf} $(use_with kerberos krb4)"
	econf --with-tmpdir=/tmp ${myconf} || die
	emake || die "emake failed"
}

src_install() {
	einstall || die

	insinto /etc/xinetd.d
	newins ${FILESDIR}/cvspserver.xinetd.d cvspserver || die "newins failed"

	dodoc BUGS ChangeLog* DEVEL* FAQ HACKING \
		MINOR* NEWS PROJECTS README* TESTS TODO
	if use emacs; then
		insinto /usr/share/emacs/site-lisp
		doins cvs-format.el || die "doins failed"
	fi

	if use doc; then
		dodoc ${DISTDIR}/cederqvist-${PV}.pdf
		dodoc ${DISTDIR}/cederqvist-${PV}.ps
		tar xjf ${DISTDIR}/cederqvist-${PV}.html.tar.bz2
		dohtml -r cederqvist-${PV}.html/*
		cd ${D}/usr/share/doc/${PF}/html/
		ln -s cvs.html index.html
	fi
}