# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit autotools-multilib eutils

DESCRIPTION="Jemalloc is a general-purpose scalable concurrent allocator"
HOMEPAGE="http://www.canonware.com/jemalloc/"
SRC_URI="http://www.canonware.com/download/${PN}/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~x86 ~x64-macos"
IUSE="debug static-libs stats"

HTML_DOCS=( doc/jemalloc.html )
PATCHES=(
	"${FILESDIR}/${PN}-3.0.0-strip-optimization.patch"
	"${FILESDIR}/${PN}-3.0.0-no-pprof.patch"
	"${FILESDIR}/${PN}-3.0.0_fix_html_install.patch"
	"${FILESDIR}/${PN}-fix-ar-call.patch"
)
MULTILIB_WRAPPED_HEADERS=( /usr/include/jemalloc/jemalloc_defs.h )
# Silence warning from enable/disable shared/static added by autotools-utils_src_configure
QA_CONFIGURE_OPTIONS=".*shared .*static"

multilib_src_configure() {
	myeconfargs=(
		$(use_enable debug)
		$(use_enable stats)
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-multilib_src_install

	if [[ ${CHOST} == *-darwin* ]] ; then
		# fixup install_name, #437362
		install_name_tool \
			-id "${EPREFIX}"/usr/$(get_libdir)/libjemalloc.1.dylib \
			"${ED}"/usr/$(get_libdir)/libjemalloc.1.dylib || die
	fi
	use static-libs || find "${ED}" -name '*.a' -delete
}