# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: Exp $

inherit eutils

MY_PN=${PN/_/-}
MY_PV=${PV:0:5}
DEB_PV=${PV:6}
S=${WORKDIR}/${MY_PN}-${MY_PV}

DESCRIPTION="pam_pgsql is a module for pam to authenticate users with PostgreSQL"
HOMEPAGE="http://sourceforge.net/projects/pam-pgsql/"

SRC_URI="mirror://sourceforge/${MY_PN}/${MY_PN}_${MY_PV}.orig.tar.gz
	http://ftp.debian.org/debian/pool/main/p/${MY_PN}/${MY_PN}_${MY_PV}-${DEB_PV}.diff.gz"
DEPEND="virtual/glibc
	>=sys-libs/pam-0.72
	>=app-crypt/mhash-0.8.18
	>=dev-db/postgresql-7.3.6"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ppc sparc alpha ~amd64"

src_unpack() {
	unpack ${A} || die
	cd ${S} || die
	epatch "${WORKDIR}/${MY_PN}_${MY_PV}-${DEB_PV}.diff" || die
}

src_compile() {
	econf || die
	emake CFLAGS="${CFLAGS}" || die
}

src_install() {
	insinto /etc
	newins "${FILESDIR}/pam_pgsql.conf" pam_pgsql.conf

	exeinto /lib/security
	doexe pam_pgsql.so
	dodoc debian/changelog README CREDITS
}