jogl-1.1_beta04.ebuild

jogl-1.1_beta04.ebuild (text/plain), 1.38 KB, created by David on 2004-07-20 23:16:14 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit java-pkg

DESCRIPTION="Java Bindings for OpenGL from the Java Gaming Initiative."

HOMEPAGE="https://jogl.dev.java.net/"

SRC_URI="https://jogl.dev.java.net/files/documents/27/5899/jogl-src.zip"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc"
S="${WORKDIR}/jogl"

DEPEND=">=dev-java/ant-1.5.3
	>=dev-java/antlr-2.7.2
	>=virtual/jdk-1.4
	virtual/opengl"

RDEPEND=">=virtual/jdk-1.4
	virtual/opengl"

src_compile() {
	# Clear the classpath
	CLASSPATH="."

	# This property is needed for JOGL's build.xml
	ANTLR="-Dantlr.jar=/usr/share/antlr/lib/antlr.jar"
	
	# build.xml is located inside the make directory
	cd make

	ant ${ANTLR} linux || {
        	eerror "Compiling jogl failed. Please make sure that ant was built with antlr support!"
		eerror " Make sure that antlr is emerged, then re-emerge ant."
		die
	}

	# Build documentation if the doc use flag is set
	if use doc; then
		einfo "Building documentation"
		ant ${ANTLR} javadoc || { 
			eerror "Failed to build documentation."
			die 
		}
	fi
}

src_install() {
	# Install the jogl main library as a Java package
	java-pkg_dojar build/jogl.jar
	
	# Install the native library
	dolib.so build/obj/libjogl.so

	# Install the documentation if the doc USE flag is set
	if use doc; then
		dohtml -r javadoc_public/*
	fi
}