htdig-3.1.6-r5.ebuild

htdig-3.1.6-r5.ebuild (text/plain), 1.45 KB, created by Renat Lumpau (RETIRED) on 2004-07-09 20:07:00 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit webapp

DESCRIPTION="HTTP/HTML indexing and searching system"
SRC_URI="http://www.htdig.org/files/${P}.tar.gz"
HOMEPAGE="http://www.htdig.org"
KEYWORDS="x86 sparc ppc ~mips amd64"
LICENSE="GPL-2"

DEPEND=">=sys-libs/zlib-1.1.3
	app-arch/unzip
	net-www/webapp-config"

export CPPFLAGS="${CPPFLAGS} -Wno-deprecated"

src_compile() {
	cd ${S}
	./configure \
		--prefix=/usr \
		--with-config-dir=/etc/${PN} \
		--with-cgi-bin-dir=${MY_CGIBINDIR} \
		--with-common-dir=/usr/share/${PN} \
		--with-database-dir=${MY_HOSTROOTDIR}/var/${PN}/db \
		--with-image-dir=${MY_HOSTROOTDIR} \
		--with-default-config-file=/etc/${PN}/${PN}.conf \
		|| die

	emake || die
}

src_install () {
	webapp_src_preinst

	make 	\
		DESTDIR=${D} \
		CONFIG_DIR=${D}/etc/${PN} \
		SEARCH_DIR=${D}/${MY_HOSTROOTDIR} \
		CGIBIN_DIR=${D}/${MY_CGIBINDIR} \
		COMMON_DIR=${D}/usr/share/${PN} \
		DATABASE_DIR=${D}/var/${PN}/db \
		IMAGE_DIR=${D}/${MY_HOSTROOTDIR} \
		DEFAULT_CONFIG_FILE=${D}/etc/${PN}/${PN}.conf \
		exec_prefix=${D}/usr \
		install || die

	dodoc ChangeLog COPYING README
	dohtml -r htdoc

	insinto /etc/conf.d
	doins installdir/htdig.conf
	sed -e "s/@DATABASE_DIR@/\/var\/${PN}\/db/" -i ${D}/etc/conf.d/htdig.conf

	dosed /etc/htdig/htdig.conf
	dosed /usr/bin/rundig

	touch ${D}/var/${PN}/db/word2root.db
	touch ${D}/var/${PN}/db/root2word.db

	webapp_src_install
}