# Copyright 1999-2004 Gentoo Technologies, Inc.                                                                         
# Distributed under the terms of the GNU General Public License v2                                                      
# $Header: $                                                                                                            

inherit distutils

DESCRIPTION="The Visualization Toolkit"
HOMEPAGE="http://www.vtk.org/"

LICENSE="VTK"
SLOT="0"
KEYWORDS="~x86"

IUSE="doc data python tcltk patented"

RDEPEND="python? ( >=dev-lang/python-2.0 )
	tcltk? ( >=dev-lang/tcl-8.2.3 )
	media-libs/jpeg
	media-libs/tiff
	media-libs/libpng
	sys-libs/zlib
	dev-libs/expat"

DEPEND=">=dev-util/cmake-1.8
	${RDEPEND}"

SHORT_PV=`echo ${PV} | cut -d. -f1,2`
SRC_URI="ftp://public.kitware.com/pub/vtk/vtk${SHORT_PV}/VTK-${PV}.tar.gz
  doc? ( ftp://public.kitware.com/pub/vtk/nightly/vtkNightlyDocHtml.tar.gz )
  data? ( mirror://sourceforge/vtk/VTKData-4.2.tar.gz )"

S=${WORKDIR}/VTK

src_compile() {

	local myconf
	
	myconf="-DCMAKE_BUILD_TYPE:STRING=Release"
	myconf="${myconf} -DCMAKE_INSTALL_PREFIX:PATH=/usr"
	myconf="${myconf} -DBUILD_SHARED_LIBS:BOOL=ON"
	myconf="${myconf} -DVTK_USE_GL2PS:BOOL=ON"
	myconf="${myconf} -DVTK_USE_HYBRID:BOOL=ON"
	myconf="${myconf} -DVTK_USE_PARALLEL:BOOL=ON"
	myconf="${myconf} -DVTK_USE_SYSTEM_JPEG:BOOL=ON"
	myconf="${myconf} -DVTK_USE_SYSTEM_PNG:BOOL=ON"
	myconf="${myconf} -DVTK_USE_SYSTEM_TIFF:BOOL=ON"
	myconf="${myconf} -DVTK_USE_SYSTEM_ZLIB:BOOL=ON"
	myconf="${myconf} -DVTK_USE_SYSTEM_EXPAT:BOOL=ON"
	myconf="${myconf} -DBUILD_TESTING:BOOL=OFF"

	use python && myconf="${myconf} -DVTK_WRAP_PYTHON:BOOL=ON"
	use tcltk && myconf="${myconf} -DVTK_WRAP_TCL:BOOL=ON"
	use patented && myconf="${myconf} -DVTK_USE_PATENTED:BOOL=ON"
	use data && myconf="${myconf} -DVTK_DATA_ROOT:STRING=usr/share/vtkdata"

	cmake ${myconf} . || die "cmake configuration failed"

	emake || die "emake failed"
}

src_install() {
	make DESTDIR=${D} install || die "make install failed"

	#for some strange reason, vtkAMRBox.h not installed by make install
	cp ${S}/Common/vtkAMRBox.h ${D}/usr/include/vtk/.

	# Fix the configuration file
	cd ${D}/usr/lib/vtk
	cat VTKConfig.cmake | sed -e "s:${D}::g" > VTKConfig.cmake.fixed
	mv -f VTKConfig.cmake.fixed VTKConfig.cmake
	
	# The Python wrapping is not installed by 'make install'
	if [ `use python` ]; then
		cd ${S}/Wrapping/Python
		docinto vtk_python
		distutils_src_install

		# Fix up the symbolic links
		distutils_python_version
		rm -f ${D}/usr/lib/python${PYVER}/site-packages/vtk_python/libvtk*Python*.so
		find ${D}/usr/lib/vtk -type f -name "libvtk*Python*.so" -exec \
		  dosym {} /usr/lib/python${PYVER}/site-packages/vtk_python \;
	fi

	#install examples and html docs; couldn't get dohtml and dodoc to work here, JJS 6/17/04
	if [ `use doc` ]; then
		dodir /usr/share/doc/vtk
		mv ${WORKDIR}/html ${D}usr/share/doc/vtk/.
		cp -r ${S}/Examples ${D}usr/share/doc/vtk/.
	fi

	#install vtk data used in many of the examples
	if [ `use data` ]; then
		dodir /usr/share/vtkdata
		mv ${WORKDIR}/VTKData-release-4-2/* ${D}usr/share/vtkdata/.
	fi

	# env.d stuff
	dodir /etc/env.d
	echo "LDPATH=/usr/lib/vtk" > ${D}/etc/env.d/40vtk
}

pkg_postinst() {
	if [ `use patented` ]; then
		ewarn "Using patented classes in commercial application requires a licence."
		ewarn "For more information read"
		ewarn "http://public.kitware.com/cgi-bin/vtkfaq?req=show&file=faq07.005.htp"
	fi
}