# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/dropbox/dropbox-1.4.7-r1.ebuild,v 1.3 2012/09/24 00:46:46 vapier Exp $

EAPI=5
inherit eutils gnome2-utils pax-utils

DESCRIPTION="Dropbox daemon (pretends to be GUI-less)"
HOMEPAGE="http://dropbox.com/"
SRC_URI="x86? ( http://dl-web.dropbox.com/u/17/dropbox-lnx.x86-${PV}.tar.gz )
	amd64? ( http://dl-web.dropbox.com/u/17/dropbox-lnx.x86_64-${PV}.tar.gz )"

LICENSE="CCPL-Attribution-NoDerivs-3.0 FTL MIT LGPL-2 openssl dropbox"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-linux"
IUSE="dedicated +librsync-bundled"
RESTRICT="mirror strip"

QA_FLAGS_IGNORED="opt/dropbox/.*"
QA_EXECSTACK="opt/dropbox/dropbox"

DEPEND="librsync-bundled? ( dev-util/patchelf )"

# Be sure to have GLIBCXX_3.4.9, #393125
RDEPEND="
	app-arch/bzip2
	dev-libs/popt
	!librsync-bundled? ( net-libs/librsync )
	net-misc/wget
	>=sys-devel/gcc-4.2.0
	sys-libs/zlib
	!dedicated? (
		media-libs/libpng:1.2
		x11-themes/hicolor-icon-theme
	)
"

src_unpack() {
	unpack ${A}
	mkdir -p "${S}"
	mv "${WORKDIR}"/.dropbox-dist/* "${S}" || die
	rmdir .dropbox-dist
}

src_prepare() {
	rm -vf libbz2* libpopt.so.0 libpng12.so.0 || die
	if use dedicated ; then
		rm -vrf *wx* images || die
	else
		mv images/hicolor/16x16/status "${T}" || die
	fi
	if use librsync-bundled ; then
		patchelf --set-rpath '$ORIGIN' _librsync.so || die
	else
		rm -vf librsync.so.1 || die
	fi
	rm -rf *.egg library.zip || die
	ln -s dropbox library.zip || die
	pax-mark cm dropbox
	mv README ACKNOWLEDGEMENTS "${T}" || die
}

src_install() {
	local targetdir="/opt/dropbox"

	insinto "${targetdir}"
	doins -r *
	fperms a+x "${targetdir}"/{dropbox,dropboxd}
	dosym "${targetdir}/dropboxd" "/opt/bin/dropbox"

	use dedicated || doicon -s 16 -c status "${T}"/status

	newinitd "${FILESDIR}"/dropbox.initd dropbox
	newconfd "${FILESDIR}"/dropbox.conf dropbox

	dodoc "${T}"/{README,ACKNOWLEDGEMENTS}
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}