aseprite-0.9.5.ebuild

file_445814.txt (text/plain), 2.00 KB, created by Tom Wijsman (TomWij) (RETIRED) on 2013-01-10 16:52:04 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit cmake-utils flag-o-matic

DESCRIPTION="Animated sprite editor & pixel art tool"
HOMEPAGE="http://www.aseprite.org"
SRC_URI="http://aseprite.googlecode.com/files/aseprite-${PV}.tar.xz"

LICENSE="GPL-2 FTL"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"

IUSE="debug memleak static-libs"

DEPEND="dev-cpp/gtest
	dev-libs/tinyxml
	media-libs/allegro:0[X,png]
	media-libs/giflib
	media-libs/libpng:0
	net-misc/curl
	sys-libs/zlib
	virtual/jpeg
	x11-libs/libX11"
RDEPEND="${DEPEND}"

PATCHES=( "${FILESDIR}"/aseprite-0.9.5-as-needed.patch )

DOCS=( docs/quickref.odt docs/files/ase.txt docs/files/fli.txt docs/files/msk.txt docs/files/pic.txt docs/files/picpro.txt )

src_prepare() {
	base_src_prepare

	# Fix to make flag-o-matic work.
	if use debug ; then
		sed -i -e '/-DNDEBUG/d' CMakeLists.txt || die
	fi

	# Only do a static link with Allegro if the user explicitly wants it.
	if ! use static-libs ; then
		sed -i -e '/-DALLEGRO_STATICLINK/d' CMakeLists.txt || die
	fi
}

src_configure() {
	use debug && append-cppflags -DDEBUGMODE -D_DEBUG

	local mycmakeargs="-DENABLE_UPDATER=OFF
		-DUSE_SHARED_ALLEGRO4=ON
		-DUSE_SHARED_CURL=ON
		-DUSE_SHARED_GIFLIB=ON
		-DUSE_SHARED_GTEST=ON
		-DUSE_SHARED_JPEGLIB=ON
		-DUSE_SHARED_LIBLOADPNG=ON
		-DUSE_SHARED_LIBPNG=ON
		-DUSE_SHARED_TINYXML=ON
		-DUSE_SHARED_ZLIB=ON
		-DFULLSCREEN_PLATFORM=ON
		$(cmake-utils_use_enable memleak)
		$(cmake-utils_use_use static-libs STATIC_LIBC)"

	cmake-utils_src_configure
}

pkg_postinst() {
	elog "Warning: aseprite might not choose the resolution correctly; so, you might need"
	elog "         to change the resolution once using the -resolution WxH[xBPP] argument."
	elog ""
	elog "         On subsequent runs, aseprite will remember the resolution you have set."
	elog ""
	elog "         For example: \`aseprite -resolution 1440x900\` when you have Full HD."
}