libpgf-6.12.24.ebuild

libpgf-6.12.24.ebuild (text/plain), 978 bytes, created by Francesco Riosa on 2012-07-06 13:26:24 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libpgf/libpgf-6.11.32.ebuild,v 1.3 2011/12/07 22:09:18 hwoarang Exp $

EAPI=4
inherit eutils autotools

DESCRIPTION="Library to load, handle and manipulate images in the PGF format"
HOMEPAGE="http://www.libpgf.org/"
#SRC_URI="http://dev.gentoo.org/~dilfridge/distfiles/${P}-src.tar.gz"
SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${PV}-latest/${P}-src.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 ~ppc x86"
IUSE="doc static-libs"

RDEPEND=""
DEPEND="doc? ( app-doc/doxygen )
	app-arch/unzip"

S=${WORKDIR}/${PN}

src_prepare() {
	if ! use doc; then
		sed -i -e "/HAS_DOXYGEN/{N;N;d}" Makefile.am || die
	fi

	epatch \
		"${FILESDIR}"/${P}-fix-memory-stream.patch

	eautoreconf
}

src_configure() {
	econf $(use_enable static-libs static)
}

src_install() {
	default

	find "${ED}" -name '*.la' -delete || die
}