dev-embedded/arduino-1.0.1.ebuild

arduino-1.0.1.ebuild (text/plain), 1.98 KB, created by Angelo Arrifano (RETIRED) on 2012-06-29 23:59:48 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="Arduino is an open-source AVR electronics prototyping platform"
HOMEPAGE="http://arduino.cc/"
SRC_URI="http://arduino.googlecode.com/files/${P}-src.tar.gz"
LICENSE="GPL-2 LGPL-2 CCPL-Attribution-ShareAlike-3.0"
SLOT="0"
KEYWORDS="~x86 ~amd64"
RESTRICT="strip binchecks"
IUSE=""

# dev-java/rxtx needs to be > 2.1 otherwise the serial connection
# will not work
RDEPEND=">=virtual/jre-1.5
dev-embedded/avrdude
sys-devel/crossdev
dev-embedded/uisp
>dev-java/rxtx-2.1"

DEPEND=">=virtual/jdk-1.5"

pkg_setup() {
	[ ! -x /usr/bin/avr-g++ ] && ewarn "Missing avr-g++; you need to crossdev -s4 avr"
}

pkg_postinst() {
	pkg_setup
}

src_prepare() {
	rm -rf build/linux/dist/tools/avrdude* \
		|| die "Cannot remove distributed avrdude"
	# Patch build/build.xml - remove local jar files
	# for rxtx and ecj (use system wide versions)
	epatch "${FILESDIR}"/${P}-build.xml.patch
	
	# Patch launcher script to include rxtx class/ld paths
	epatch "${FILESDIR}"/${P}-script.patch

	# Remove the rxtx libraries to ensure the system
	# libraries are used
	rm build/linux/dist/lib/*

	java-utils-2_src_prepare
}

src_compile() {
	cd build
	EANT_BUILD_TARGET=build
	java-pkg-2_src_compile
}

src_install() {
	insinto "/usr/share/${P}/"
	doins -r app build core hardware libraries
	
	fowners -R root:uucp "/usr/share/${P}/hardware"
	dodir /usr/bin
	printf "#!/bin/sh\nexec /usr/share/${P}/build/linux/work/arduino" \
			> "${D}/usr/bin/arduino"
	fperms guo=rx "/usr/bin/arduino"
	fperms guo=rx "/usr/share/${P}/build/linux/work/arduino"

	# use system avrdude
	# patching class files is too hard
	dosym /usr/bin/avrdude "/usr/share/${P}/hardware/tools/avrdude"
	dosym /etc/avrdude.conf "/usr/share/${P}/hardware/tools/avrdude.conf"

	# IDE tries to compile these libs at first start up
	# WTF??
	#fperms -R g+w "/usr/share/${P}/libraries"

	dodoc readme.txt
}