works for me

shiboken-1.1.0.ebuild (text/plain), 1.54 KB, created by Davide Pesavento on 2012-03-01 23:17:21 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/shiboken/shiboken-1.1.0.ebuild,v 1.1 2012/01/15 11:23:11 hwoarang Exp $

EAPI=4

CMAKE_IN_SOURCE_BUILD="1"
PYTHON_DEPEND="2:2.6 3:3.2"
PYTHON_EXPORT_PHASE_FUNCTIONS="1"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="*-jython 2.7-pypy-*"

inherit multilib cmake-utils python

DESCRIPTION="A tool for creating Python bindings for C++ libraries"
HOMEPAGE="http://www.pyside.org/"
SRC_URI="http://www.pyside.org/files/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

DEPEND=">=dev-python/apiextractor-0.10.10
	>=dev-python/generatorrunner-0.6.16
	>=x11-libs/qt-core-4.7.0:4"
RDEPEND="${DEPEND}
	!dev-python/boostpythongenerator"

DOCS=( ChangeLog )

src_configure() {
	configuration() {
		local mycmakeargs=(
			$(cmake-utils_use_build test TESTS)
		)
		if [[ $(python_get_version -l --major) == 3 ]]; then
			mycmakeargs+=(
				-DUSE_PYTHON3=ON
				-DPYTHON3_INCLUDE_DIR="$(python_get_includedir)"
				-DPYTHON3_LIBRARY="$(python_get_library)"
			)
		fi
		CMAKE_USE_DIR="${BUILDDIR}" cmake-utils_src_configure
	}
	python_execute_function -s configuration
}

src_compile() {
	compilation() {
		CMAKE_USE_DIR="${BUILDDIR}" cmake-utils_src_make
	}
	python_execute_function -s compilation
}

src_install() {
	installation() {
		CMAKE_USE_DIR="${BUILDDIR}" cmake-utils_src_install
		mv "${ED}"usr/$(get_libdir)/pkgconfig/shiboken{,-${PYTHON_ABI}}.pc || die
	}
	python_execute_function -s installation
}