# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="wwwoffle = WWW Offline Explorer, an adv. caching proxy especially suitable for nonpermanent (e.g. dialup) Internet connections"

SRC_URI="ftp://ftp.demon.co.uk/pub/unix/httpd/${P}.tgz
	ftp://ftp.ibiblio.org/pub/Linux/apps/www/servers/${P}.tgz"

HOMEPAGE="http://www.gedanken.demon.co.uk/"
KEYWORDS="~x86"
SLOT="0"
LICENSE="GPL-2"
IUSE="ipv6"

DEPEND=">=sys-apps/sed-4
	sys-apps/gawk
	dev-lang/perl
	sys-devel/flex
	sys-libs/zlib
	sys-devel/gcc
	virtual/glibc"

RDEPEND="sys-libs/zlib"

pkg_setup() {
	# Add a wwwoffle user
	enewgroup wwwoffle
	enewuser wwwoffle -1 /bin/false /var/spool/wwwoffle wwwoffle
}

src_unpack(){
	unpack ${A}
	cd ${S}
	sed -i -e 's#$(TAR) xpf #$(TAR) --no-same-owner -xpf #' cache/Makefile.in
	sed -i -e "s#^docdir=.*#docdir=\$(DESTDIR)\${prefix}/share/doc/${P}#" doc/Makefile.in
	# change to user wwwoffle
	sed -i -e "s#\#\(run-[gu]id\).*#\1 = wwwoffle#" conf/wwwoffle.conf

	### adjust path for htdig (needs inherit webapp-apache)
	## questions: webapp-apache deprecated?
	##            function shouldn't be in src_unpack?
	##            useless function, always /var/www/localhost/cgi-bin
	#
	#webapp-determine-cgibindir
	#sed -i -e "s#/usr/local/bin#${HTTPD_CGIBIN}#" cache/search/htdig/scripts/wwwoffle-htsearch
	#sed -i -e "s#/usr/local/bin#/var/www/localhost/cgi-bin#" cache/search/htdig/scripts/wwwoffle-htsearch
	sed -i -e '13i\
PATH=$PATH:/var/www/localhost/cgi-bin # Gentoo location' cache/search/htdig/scripts/wwwoffle-htsearch
}

src_compile() {
	local myconf
	myconf="`use_with ipv6`"
	econf --with-confdir=/etc ${myconf} || die
	emake || die
}

src_install() {
	make DESTDIR=${D} install || die

	# install the wwwoffled init script
	exeinto /etc/init.d
	doexe ${FILESDIR}/{wwwoffled-online,wwwoffled}

	# keep spool
	keepdir /var/spool/wwwoffle/{http,outgoing,monitor,lasttime,prevtime1,lastout,local}
	# empty dirs are removed during update
	keepdir /var/spool/wwwoffle/search/{mnogosearch/db,htdig/tmp,htdig/db-lasttime,htdig/db}
	# del empty doc dirs
	rmdir ${D}/usr/share/doc/${P}/{it,nl,ru}
}

pkg_postinst() {
	cd ${ROOT}/var/spool/
	chown -R wwwoffle:wwwoffle wwwoffle
}