# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

MY_P="${P/./_}"

DESCRIPTION="A scrolling, platform-jumping, key-collecting, ancient pyramid exploring game."
HOMEPAGE="http://abe.sourceforge.net"
SRC_URI="mirror://sourceforge/abe/${MY_P}.tar.gz"

LICENSE="public-domain"
KEYWORDS="x86"
IUSE=""

RDEPEND=">=media-libs/libsdl-1.2.3
	>=media-libs/sdl-mixer-1.2.5"

DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

S="${WORKDIR}/${MY_P}"
DEST_DIR="${GAMES_DATADIR}/${PN}"

src_unpack() {
	unpack ${A}
	cd ${S}/src

	# Modify paths to resources
	sed -i -e "s:\"images\":\"${DEST_DIR}/images\":" Image.h || die "sed Image.h failed"
	sed -i -e "s:\"maps\":\"${DEST_DIR}/maps\":" Map.h MapIO.h || die "sed Map.h MapIO.h failed"
	sed -i -e "s:\"sounds\":\"${DEST_DIR}/sounds\":" Sound.h || die "sed Sound.h failed"

	epatch ${FILESDIR}/${PV}-gentoo-paths.patch
}

src_compile() {
	./autogen.sh || die "autogen.sh failed"

	egamesconf || die "egamesconf failed"

	emake || die "emake failed"
}

src_install() {
	local f

	for f in images sounds maps
	do
		insinto ${DEST_DIR}/${f}
		doins ${f}/*
	done

	dogamesbin abe

	prepgamesdirs
}