# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:  $

EAPI=2

PYTHON_DEPEND="2:2.4"

inherit eutils flag-o-matic python

DESCRIPTION="The Open Source Integration Platform for Numerical Simulation - GUI component"
HOMEPAGE="http://www.salome-platform.org"
SRC_URI="http://files.opencascade.com/Salome/Salome${PV}/src${PV}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="debug doc opengl +paraview -vtk"

RDEPEND="
	>=sci-misc/salome-kernel-${PV}
	>=net-misc/omniORB-4.1.5
	>=dev-python/omniorbpy-3.5
	>=sci-libs/hdf5-1.8.4
	>=dev-libs/boost-1.46.1
	>=x11-libs/qt-core-4.6
	>=x11-libs/qt-gui-4.6
	>=x11-libs/qt-opengl-4.6
	>=x11-libs/qwt-5.2.1
	>=dev-python/PyQt4-4.7.3
	vtk? ( >=sci-libs/vtk-5.8[python,mpi] )
	paraview? ( >=sci-visualization/paraview-3.10 )
	>=sci-libs/opencascade-6.3
	app-text/dgs
	opengl?  ( virtual/opengl )
	debug?   ( dev-util/cppunit )"
DEPEND="${RDEPEND}
	>=app-doc/doxygen-1.7.3
	>=media-gfx/graphviz-2.26.3
	>=dev-python/sip-4.10.2
	dev-lang/swig
	dev-libs/libxml2:2"

MODULE_NAME="GUI"
S="${WORKDIR}/${MODULE_NAME}_SRC_${PV}"
INSTALL_DIR="/opt/salome-${PV}/${MODULE_NAME}"
GUI_ROOT_DIR="/opt/salome-${PV}/${MODULE_NAME}"

pkg_setup() {
	[[ $(python_get_version) > 2.6 ]] && \
		ewarn "Python 2.6 is highly recommended for Salome..."
	python_set_active_version 2
	append-ldflags $(no-as-needed)
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-qt4-path.patch
	epatch "${FILESDIR}"/${P}-vtk.patch

	if has_version ">=sci-libs/opencascade-6.5" ; then
	epatch "${FILESDIR}"/${P}-occ-6.5.patch
	fi

	if has_version ">=x11-libs/qt-gui-4.7" ; then
	epatch "${FILESDIR}"/${P}-qt-4.7.patch
	fi

	rm -r -f autom4te.cache
	./clean_configure
	./build_configure
}

src_configure() {
	local vtk_confargs=""
	local vtk_suffix=$(echo ${VTK_DIR} | cut -d k -f2)

	if use paraview ; then
		test -e /usr/include/paraview-3.10/vtkGL2PSExporter.h \
			|| die "recompile paraview with -DVTK_USE_GL2PS=on"
	fi

	if use vtk && use paraview ; then
		eerror "You have selected both vtk and paraview useflags, choose one"
		die "invalid useflag combination"
	fi

	if ! use vtk && ! use paraview ; then
		eerror "You have to enable either the vtk or paraview useflag"
		die "invalid useflag combination"
	fi

	if use vtk ; then
	vtk_confargs="--with-vtk=${VTKHOME} --with-vtk-version=${vtk_suffix}
	--with-paraview=dummy"
	fi

	if use paraview ; then
	vtk_confargs="--with-vtk=dummy --with-paraview=/usr"
	fi

	econf --prefix=${INSTALL_DIR} \
	      --datadir=${INSTALL_DIR}/share/salome \
	      --docdir=${INSTALL_DIR}/doc/salome \
	      --infodir=${INSTALL_DIR}/share/info \
	      --libdir=${INSTALL_DIR}/$(get_libdir)/salome \
	      --with-python-site=${INSTALL_DIR}/$(get_libdir)/python$(python_get_version)/site-packages/salome \
	      --with-python-site-exec=${INSTALL_DIR}/$(get_libdir)/python$(python_get_version)/site-packages/salome \
		  --with-qt=/usr \
		  --with-qwt=/usr \
		  --with-qwt_inc=/usr/include/qwt5 \
		  --with-pyuic4=/usr/bin/pyuic4 \
		  ${vtk_confargs} \
	      $(use_enable debug ) \
	      $(use_enable !debug production ) \
	      $(use_with debug cppunit /usr ) \
	      $(use_with opengl opengl /usr) \
		|| die "econf failed"
}

src_compile() {
	MAKEOPTS="-j1" emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	use amd64 && dosym ${INSTALL_DIR}/lib64 ${INSTALL_DIR}/lib

	echo "${MODULE_NAME}_ROOT_DIR=${INSTALL_DIR}" > ./90${P}
	echo "LDPATH=${INSTALL_DIR}/$(get_libdir)/salome" >> ./90${P}
	echo "PATH=${INSTALL_DIR}/bin/salome" >> ./90${P}
	echo "PYTHONPATH=${INSTALL_DIR}/$(get_libdir)/python$(python_get_version)/site-packages/salome" >> ./90${P}
	doenvd 90${P}
	rm adm_local/Makefile adm_local/unix/Makefile adm_local/cmake_files/Makefile \
		adm_local/unix/config_files/Makefile

	insinto "${INSTALL_DIR}"
	doins -r adm_local
	use doc && dodoc AUTHORS INSTALL NEWS README
}

pkg_postinst() {
	elog "Run \`env-update && source /etc/profile\`"
	elog "now to set up the correct paths."
	elog ""
}