proof-of-concept ebuild for 2.0_alpha1

owncloud-2.0_alpha1.ebuild (text/plain), 1.25 KB, created by Dennis Schridde on 2011-09-02 10:46:53 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/owncloud/owncloud-1.2.ebuild,v 1.1 2011/04/27 12:10:20 alexxy Exp $

inherit webapp eutils depend.php versionator

MY_PV=$(replace_version_separator 2 '-')
MY_P=${PN}-${MY_PV}

DESCRIPTION="Web-based storage application where all your data is under your own control"
HOMEPAGE="http://owncloud.org"
SRC_URI="http://owncloud.org/releases/${MY_P}.tar.bz2"

LICENSE="GPL-3"
KEYWORDS="~amd64 ~x86"
IUSE=""

need_httpd_cgi
need_php_httpd

S="${WORKDIR}/${PN}"

DOCS="README"

pkg_setup() {
	flags="json xmlwriter zip"
	webapp_pkg_setup
	has_php
	require_php_with_use ${flags}
}

src_install() {
	webapp_src_preinst

	dodoc ${DOCS} || die
	rm -f ${DOCS} || die
	insinto "${MY_HTDOCSDIR}"
	doins -r . || die
	dodir "${MY_HTDOCSDIR}"/data || die
	webapp_serverowned "${MY_HTDOCSDIR}"/data
	webapp_serverowned "${MY_HTDOCSDIR}"/config

	webapp_src_install
}

pkg_preinst() {
	if has_version "<${CATEGORY}/${P}" ; then
		elog "The webdav address has changed from webdav://ADDRESS/webdav/owncloud.php to webdav://ADDRESS/files/webdav.php"
		elog "Make sure to erase your config file and all tabels in the database before using owncloud"
	fi
}