slimlock-0.9.ebuild

slimlock-0.9.ebuild (text/plain), 1.05 KB, created by Ian Stakenvicius (RETIRED) on 2011-08-23 23:44:19 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit toolchain-funcs

DESCRIPTION="screen locker borrowing the interface of the SLiM login-manager"
HOMEPAGE="http://programsthatsmellgood.com/slimlock/"
SRC_URI="https://github.com/joelburget/slimlock/tarball/v${PV} -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="x11-libs/libX11
	x11-libs/libXft
	media-libs/freetype
	media-libs/imlib2
	virtual/pam"
RDEPEND="${DEPEND}
	x11-misc/slim[pam]"

src_unpack() {
	default_src_unpack
	# to address the github hash
	mv *-${PN}-* "${S}"
}

src_prepare() {
	sed -i \
		-e "s/LDFLAGS=\(.*\)/LIBS=\1/" \
		-e "s/-o \$(NAME)/-o \$(NAME) \$(LIBS)/" \
		-e "/MANDIR/d" \
		-e "s/CFLAGS=/MYCFLAGS=/" \
		-e "s/\$(CFLAGS)/\$(CFLAGS) \$(MYCFLAGS)/" \
		Makefile || die "sed failed"
}

src_compile() {
	emake	CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		VERSION=${PV} \
		PREFIX="${EPREFIX}"/usr \
		CFGDIR="${EPREFIX}"/etc
}

src_install() {
	default_src_install
	doman ${PN}.1
}