# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/games-puzzle/krystaldrop/krystaldrop-0.7.2.ebuild,v 1.1 2004/02/28 02:32:20 mr_bones_ Exp $

inherit eutils games

# Despite the date on the directory, the source is up-to-date
S="${WORKDIR}/AlephOne-20030605"
MY_P=${P/alephone/AlephOne}

DESCRIPTION="Marathon open source project"
HOMEPAGE="http://source.bungie.org
	http://orbitalarm.bungie.org/downloads/M1A1-SDL.html"
SRC_URI="http://marathon.sourceforge.net/nightly/builds/${MY_P}.tar.gz
	m1a1? ( http://archives2.bungie.org/a1sdl/m1a1_sdl.zip
		revival? ( ftp://ftp3.bungie.org/archives/m1a1.shapes/m1a1.revival256x256png.zip ))"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE="m1a1 revival"

RDEPEND="virtual/opengl
	>=media-libs/libsdl-1.2.5
	media-libs/sdl-image
	media-libs/sdl-net
	dev-lang/lua"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4
	m1a1? ( app-arch/unzip )"

src_unpack() {
	unpack ${MY_P}.tar.gz
	epatch "${FILESDIR}/alephone-missing-files.patch"

	if [ `use m1a1` ]; then
		einfo "Unpacking Marathon One Scenario for Aleph One"
		cd ${WORKDIR}
		unzip -qn ${DISTDIR}/m1a1_sdl.zip || \
			die "unzip m1a1_sdl.zip failed"
		cd "${WORKDIR}/M1A1 SDL"
		for f in Images Map Music Shapes Sounds ; do
			mv "M1A1 ${f}" ${f}
		done
		sed -i \
			-e "/>M1A1 .*</ s:>M1A1 :>:" Scripts/settings.mml
		if [ `use revival` ]; then
			einfo "Unpacking Marathon One Revival Pack"
			unzip -qn ${DISTDIR}/m1a1.revival256x256png.zip || \
				die "unzip m1a1.revival256x256png.zip failed"
			mv "Revival PNG for M1A1/revival_png.mml" Scripts/
		fi
	fi
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS README \
		docs/Cheat_Codes
	dohtml docs/MML.html

	local datadir=${D}${GAMES_DATADIR}/${PN/alephone/AlephOne}
	if [ `use m1a1` ]; then
		einfo "Installing Marathon One Scenario for Aleph One"
		cd "${WORKDIR}/M1A1 SDL"
		mv "ReadMe M1A1 SDL.html" ReadMe_M1A1_SDL.html
		dohtml ReadMe_M1A1_SDL.html
		for f in Images Map Music Scripts Shapes Sounds Tracks ; do
			mv ${f} ${datadir}
		done
		if [ `use revival` ]; then
			einfo "Installing Marathon One Revival Pack"
			mv "Revival PNG for M1A1/Read Me Revival.html" Read_Me_Revival.html
			dohtml Read_Me_Revival.html
			mv "Revival PNG for M1A1/Revival PNG" ${datadir}
		fi
	fi

	prepgamesdirs
}