# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

SUPPORT_PYTHON_ABIS="1"
PYTHON_DEPEND="2:2.6"
RESTRICT_PYTHON_ABIS="2.[45] 3.*"

inherit distutils eutils multilib

DESCRIPTION="Mercurial GUI command line tool hgqt"
HOMEPAGE="http://tortoisehg.bitbucket.org"
SRC_URI="http://bitbucket.org/${PN}/targz/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc nautilus"

RDEPEND="dev-python/PyQt4
	>=dev-vcs/mercurial-1.6.3
	>=dev-python/iniparse-0.4
	dev-python/qscintilla-python
	nautilus? ( dev-python/nautilus-python )"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/sphinx-1.0.3 )"

src_compile() {
	# Remove unwanted languages.
	for u in ${LINGUAS}; do
		[ -f "i18n/tortoisehg/${u}.po" ] && \
			mv -f i18n/tortoisehg/${u}.po i18n/
	done
	find i18n/tortoisehg/ -type f -name "*.po" -delete
	find i18n/ -maxdepth 1 -type f -name "*.po" \
		-exec mv -f {} i18n/tortoisehg/ \;

	distutils_src_compile

	if use doc ; then
		emake -C doc html || die
	fi
}

src_install() {
	# make the install respect multilib.
	sed -i -e "s:lib/nautilus/extensions-2.0/python:$(get_libdir)/nautilus/extensions-2.0/python:" setup.py || die

	distutils_src_install
	dodoc doc/ReadMe*.txt doc/TODO || die

	if use doc ; then
		dohtml -r doc/build/html || die
	fi

	sed -i -e "/^Icon/s:tortoisehg_logo:${PN}:" contrib/*.desktop
	domenu contrib/*.desktop
	newicon icons/svg/thg_logo.svg ${PN}.svg

	if ! use nautilus; then
		einfo "Excluding Nautilus extension."
		rm -fR "${D}"/usr/$(get_libdir)/nautilus || die
	fi
}