Ebuild for 2.1.3

zeromq-2.1.3.ebuild (text/plain), 1.23 KB, created by Dirkjan Ochtman (RETIRED) on 2011-03-28 14:52:24 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

# NOTES:
# 1- use flag 'pgm' (OpenPGM support) must be masked by profiles for ARM archs;

EAPI=3
WANT_AUTOCONF="2.5"
inherit autotools

DESCRIPTION="ZeroMQ is a brokerless messaging kernel with extremely high performance."
HOMEPAGE="http://www.zeromq.org"
SRC_URI="http://download.zeromq.org/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pgm test doc static-libs"

RDEPEND=""
DEPEND="pgm? (
		dev-util/pkgconfig
		net-libs/openpgm
	)
	doc? (
		app-text/asciidoc
		app-text/xmlto
	)
	sys-apps/util-linux"

src_prepare() {
	einfo "Removing bundled OpenPGM library"
	rm -r ${S}/foreign/openpgm || die
	epatch "${FILESDIR}/${P}"-configure.patch || die
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		$(use_with doc documentation) \
		$(use_with pgm) \
		${EXTRA_ECONF}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc NEWS README AUTHORS ChangeLog || die "dodoc failed."

	# remove useless .la files
	find "${D}" -name '*.la' -delete

	# remove useless .a (only for non static compilation)
	use static-libs || find "${D}" -name '*.a' -delete
}